[远航笔记流水账]六套大漠多线程高级第一章

.版本 2
.支持库 iext
.支持库 spec

.子程序 超级列表框刷新列表
.局部变量 进程窗口句柄数组, 整数型, , "0"
.局部变量 进程子窗口句柄数组, 整数型, , "0"
.局部变量 进程窗口标题数组, 文本型, , "0"
.局部变量 i, 整数型
.局部变量 ii, 整数型
.局部变量 j, 整数型
.局部变量 当前超级列表框内容数组, 超级列表框多线程记录结构, , "0"
.局部变量 当前游戏窗口信息数组, 超级列表框多线程记录结构, , "0"
.局部变量 新增的游戏窗口信息数组, 超级列表框多线程记录结构, , "0"
.局部变量 是否找到相符的窗口句柄, 整数型
.局部变量 最终最新的超级列表框内容数组, 超级列表框多线程记录结构, , "0"
.局部变量 临时超级列表框多线程记录结构变量, 超级列表框多线程记录结构
.局部变量 当前最终最新的超级列表框内容数组的最后一个元素的id, 整数型

' 暂时没考虑多线程下同时使用的冲突问题
' 问题：按照老师的写法 一旦中途需要关闭其中一个窗口 或者新开几个游戏窗口 这些关闭的窗口和新增的窗口会让超级列表框的记录的id重新改变 但是重要的是 这些id其实是和大漠多线程信息数组一一对应  直接改变了超级列表框记录对应的Id 但是大漠多线程信息数组里面的id值 不能轻易改变 因为它不单单是个id数字 还对应着一个大漠对象和线程  这个大漠对象还可能正在绑定之前的指定窗口在运行线程 脚本 你总不能每次新增窗口或者关闭一个窗口就把所有窗口解绑  线程都关闭 然后读取新的id重新开启新线程 重新再次绑定窗口
' 个人解决办法 刷新的时候 先把当前的超级列表框的所有游戏窗口信息都记录到一个数组 然后 再把当前真正在运行的游戏窗口和信息也记录到另外一个表 ，然后2个数组对比 获取到新增的窗口的信息 记录到一个新增数组 然后对比得到了 哪些窗口是已经关闭的 也记录到关闭数组 然后就是在 原来的超级列表框记录的基础上进行删减和增加操作（原来已经存在的窗口 id 标题 当前状态都不用变动 在已经关闭的窗口对应的记录那里  填写进一个新增的窗口信息 但是id和原来的保持一样 当然 替换之前自然要到大漠多线程信息数组查看下这个窗口对应的大漠对象是否还在绑定 线程是否关闭 没有就要顺手一关 然后再替换） 来构成一个最新的数组 然后把数组写入到超级列表框内

' 1. 取得当前所有的进程名对应的窗口的对应窗口句柄 窗口标题 子窗口句柄 并把这些信息写入一个数组
进程_名取所有句柄2 (#游戏进程名, 进程窗口句柄数组)  ' 窗口句柄
.计次循环首 (取数组成员数 (进程窗口句柄数组), i)
    加入成员 (进程子窗口句柄数组, 窗口_取句柄 (进程窗口句柄数组 [i], , “Edit”, ))  ' 子窗口句柄
    加入成员 (进程窗口标题数组, 窗口_取标题 (进程窗口句柄数组 [i]))  ' 窗口标题

    ' '（1）获取现在所有游戏窗口的信息写入到另外一个数组 该数组存储现在的所有窗口信息
    临时超级列表框多线程记录结构变量.id ＝ i
    临时超级列表框多线程记录结构变量.窗口标题 ＝ 进程窗口标题数组 [i]
    临时超级列表框多线程记录结构变量.窗口句柄 ＝ 进程窗口句柄数组 [i]
    临时超级列表框多线程记录结构变量.子窗口句柄 ＝ 进程子窗口句柄数组 [i]
    临时超级列表框多线程记录结构变量.当前状态 ＝ “等待”
    加入成员 (当前游戏窗口信息数组, 临时超级列表框多线程记录结构变量)
    辅助延时 (1)
.计次循环尾 ()
' 调试输出 (“当前游戏窗口信息数组：↓↓↓↓↓↓↓”)
.' 计次循环首 (取数组成员数 (当前游戏窗口信息数组), i)
    ' 调试输出 (当前游戏窗口信息数组 [i].窗口标题)
    ' 辅助延时 (1)
.' 计次循环尾 ()
' 调试输出 (“当前游戏窗口信息数组：↑↑↑↑↑↑↑”)

' 2 获取当前超级列表框记录的之前的所有游戏窗口的信息 并写入到一个数组
.计次循环首 (_启动窗口.超级列表框1.取表项数 (), i)
    临时超级列表框多线程记录结构变量.id ＝ 到整数 (_启动窗口.超级列表框1.取标题 (i － 1, 0))
    临时超级列表框多线程记录结构变量.窗口标题 ＝ _启动窗口.超级列表框1.取标题 (i － 1, 1)
    临时超级列表框多线程记录结构变量.窗口句柄 ＝ 到整数 (_启动窗口.超级列表框1.取标题 (i － 1, 2))
    临时超级列表框多线程记录结构变量.子窗口句柄 ＝ 到整数 (_启动窗口.超级列表框1.取标题 (i － 1, 3))
    临时超级列表框多线程记录结构变量.当前状态 ＝ _启动窗口.超级列表框1.取标题 (i － 1, 4)
    加入成员 (当前超级列表框内容数组, 临时超级列表框多线程记录结构变量)
    辅助延时 (1)
.计次循环尾 ()
' 调试输出 (“当前超级列表框内容数组：↓↓↓↓↓↓↓”)
.' 计次循环首 (取数组成员数 (当前超级列表框内容数组), i)
    ' 调试输出 (当前超级列表框内容数组 [i].窗口标题)
    ' 辅助延时 (1)
.' 计次循环尾 ()
' 调试输出 (“当前超级列表框内容数组：↑↑↑↑↑↑↑”)

' 3.两个数组对比得到新增的窗口信息写入一个数组
.计次循环首 (取数组成员数 (当前游戏窗口信息数组), i)
    是否找到相符的窗口句柄 ＝ -1
    .计次循环首 (取数组成员数 (当前超级列表框内容数组), j)
        .如果真 (当前游戏窗口信息数组 [i].窗口句柄 ＝ 当前超级列表框内容数组 [j].窗口句柄)
            是否找到相符的窗口句柄 ＝ 1
            跳出循环 ()
        .如果真结束
        辅助延时 (1)
    .计次循环尾 ()
    .如果真 (是否找到相符的窗口句柄 ＝ -1)
        ' 把这个元素添加到新数组 这个数组就是存储新增的窗口信息
        加入成员 (新增的游戏窗口信息数组, 当前游戏窗口信息数组 [i])
    .如果真结束

    辅助延时 (1)
.计次循环尾 ()

' 调试输出 (“新增的游戏窗口信息数组：↓↓↓↓↓↓↓”)
.' 计次循环首 (取数组成员数 (新增的游戏窗口信息数组), i)
    ' 调试输出 (新增的游戏窗口信息数组 [i].窗口标题)
    ' 辅助延时 (1)
.' 计次循环尾 ()
' 调试输出 (“新增的游戏窗口信息数组：↑↑↑↑↑↑↑”)


' 4.循环遍历老的超级列表框记录数组 找到已经被关闭的窗口记录 先检查其id对应的线程和大漠对象是否解绑 没有则关闭和解绑 然后在已经关闭的窗口记录位置 用新增窗口信息替换它 不过保留原始id,然后把新的窗口记录信息写到最终的数组里面
' 最终最新的超级列表框内容数组
.计次循环首 (取数组成员数 (当前超级列表框内容数组), i)
    是否找到相符的窗口句柄 ＝ -1
    .计次循环首 (取数组成员数 (当前游戏窗口信息数组), j)
        .如果真 (当前超级列表框内容数组 [i].窗口句柄 ＝ 当前游戏窗口信息数组 [j].窗口句柄)
            是否找到相符的窗口句柄 ＝ 1
            跳出循环 ()
        .如果真结束
        辅助延时 (1)
    .计次循环尾 ()
    .如果 (是否找到相符的窗口句柄 ＝ -1)
        ' 说明当前的列表框的记录对应的窗口句柄已经失效了 要检查下其对应的句柄 和 对应的线程是否存在
        调试输出 (“标题：[” ＋ 到文本 (当前超级列表框内容数组 [i].窗口标题) ＋ “] id:[” ＋ 到文本 (当前超级列表框内容数组 [i].id) ＋ “]属于被删除的窗口 ”)

        .如果真 (大漠多线程信息 [i].窗口句柄 ＞ 0 且 大漠多线程信息 [i].线程句柄 ＞ 0)
            ' 判断下对应的线程是否还在运行 (线程_取中止线程退出代码 ())还在运行则停止线程 解绑窗口 (大漠.绑定_判断 ())
            .如果真 (线程_取中止线程退出代码 (大漠多线程信息 [i].线程句柄) ＝ 2)
                线程_强制结束 (大漠多线程信息 [i].线程句柄)
                线程_关闭句柄 (大漠多线程信息 [i].线程句柄)
                大漠多线程信息 [i].线程句柄 ＝ 0
                调试输出 (“线程[” ＋ 到文本 (i) ＋ “] 关闭完毕”)
            .如果真结束

            .如果真 (大漠多线程信息 [i].大漠.绑定_判断 (大漠多线程信息 [i].整数参数一) ＝ 1)  ' 整数参数一里面存放的就是子窗口句柄
                大漠多线程信息 [i].大漠.解绑 ()
                大漠多线程信息 [i].窗口句柄 ＝ 0
                调试输出 (“绑定[” ＋ 到文本 (i) ＋ “] 解绑完毕”)
            .如果真结束

        .如果真结束
        ' 这里从 新增的游戏窗口信息数组 取第一个元素来插入这里 如果这个数组已经为空了 那么这个元素的所有内容为空得了
        .如果 (取数组成员数 (新增的游戏窗口信息数组) ＞ 0)
            加入成员 (最终最新的超级列表框内容数组, 新增的游戏窗口信息数组 [1])
            最终最新的超级列表框内容数组 [取数组成员数 (最终最新的超级列表框内容数组)].id ＝ 当前超级列表框内容数组 [i].id  ' 继承了之前的那个id 虽然以前的窗口已经不在了
            删除成员 (新增的游戏窗口信息数组, 1, 1)

        .否则

        .如果结束


    .否则
        ' 找到了相符的句柄就不用多费劲了
        加入成员 (最终最新的超级列表框内容数组, 当前超级列表框内容数组 [i])
        调试输出 (“标题：[” ＋ 到文本 (当前超级列表框内容数组 [i].窗口标题) ＋ “] id:[” ＋ 到文本 (当前超级列表框内容数组 [i].id) ＋ “]存在于上次的列表框记录 直接插入新数组”)
    .如果结束

    辅助延时 (1)
.计次循环尾 ()
' 5 看看新增的窗口数组里面还有没有剩余的元素 有则追尾给最终数组加上去 注意对应的id要接着最终数组最后一个元素的id+1 不能用计次循环的i
.如果真 (取数组成员数 (新增的游戏窗口信息数组) ＞ 0)
    .计次循环首 (取数组成员数 (新增的游戏窗口信息数组), i)
        当前最终最新的超级列表框内容数组的最后一个元素的id ＝ 最终最新的超级列表框内容数组 [取数组成员数 (最终最新的超级列表框内容数组)].id
        加入成员 (最终最新的超级列表框内容数组, 新增的游戏窗口信息数组 [i])
        ' 新增的游戏窗口信息数组 [i].id ＝ 当前最终最新的超级列表框内容数组的最后一个元素的id+1
        辅助延时 (1)
    .计次循环尾 ()

.如果真结束
' 调试输出 (“最终最新的超级列表框内容数组：↓↓↓↓↓↓↓”)
.' 计次循环首 (取数组成员数 (最终最新的超级列表框内容数组), i)
    ' 调试输出 (最终最新的超级列表框内容数组 [i].窗口标题)
    ' 辅助延时 (1)
.' 计次循环尾 ()
' 调试输出 (“最终最新的超级列表框内容数组：↑↑↑↑↑↑↑”)

' 6 清理列表框
_启动窗口.超级列表框1.全部删除 ()

' 7 把刚才获取的最终数组信息写入到超级列表框
.计次循环首 (取数组成员数 (最终最新的超级列表框内容数组), i)
    _启动窗口.超级列表框1.插入表项 (, , , , , )
    _启动窗口.超级列表框1.置标题 (i － 1, 0, 到文本 (最终最新的超级列表框内容数组 [i].id))
    _启动窗口.超级列表框1.置标题 (i － 1, 1, 最终最新的超级列表框内容数组 [i].窗口标题)
    _启动窗口.超级列表框1.置标题 (i － 1, 2, 到文本 (最终最新的超级列表框内容数组 [i].窗口句柄))
    _启动窗口.超级列表框1.置标题 (i － 1, 3, 到文本 (最终最新的超级列表框内容数组 [i].子窗口句柄))
    _启动窗口.超级列表框1.置标题 (i － 1, 4, “等待.”)
    辅助延时 (1)
.计次循环尾 ()

.版本 2
.支持库 spec

.局部变量 aa, 整数型

调试输出 (“[” ＋ 到文本 (aa) ＋ “]”)
.如果 (aa ＝ 0)
    调试输出 (0)

.否则
    调试输出 (“不是0”)

.如果结束
调试输出 (aa)