batch-file - 提取两个字符串之间的子字符串

Question

这是我的代码段：

set CMS_SQL="cms91_to_913.json cms913_to_9132.json cms9132_to_9133.json cms9133_to_10100.json"
set CMS_FROM_VERSION="cms913_"
set CMS_TO_VERSION="to_9133.json"

CMS_FROM_VERSION和CMS_TO_VERSION都是变量

我想从中提取子"cms913_to_9132.json cms9132_to_9133.json"字符串%CMS_SQL%

只想获取%CMS_FROM_VERSION% and %CMS_TO_VERSION%包含这两个变量值之间的子字符串

不想使用文件来执行此操作，也不想硬编码数字来获取子字符串，因为这两个字符串是变量。

如何提取这两个字符串之间的子字符串？谢谢

标签： batch-file

Answer 1

重申我的评论，以下不知道或计算子字符串的长度，它只是从字符串中删除前两个和最后两个字符：

Set "String=AB134SSPQS"
Set "subString=%String:~2,-2%"
Echo %subString%

如果ABandQS在所需的子字符串之前和之后，但不一定开始和开始字符串，那么也许这对您有用：

Rem Looking for a file.txt substring preceded by AB and succeeded by QS
@Echo Off
For /F "Delims=" %%A In ('FindStr /I "AB.*QS" "file.txt"') Do Call :Sub "%%A"
Pause
GoTo :EOF

:Sub
Set "Line=%~1"
Set "Up2Sub=%Line:*AB=%"
Set "SubStr=%Up2Sub:QS="&:"%"
Echo %SubStr%
Exit /B

我不得不编造一个场景，（请参阅Rem），因为您没有提供足够的信息来作为答案的基础。

编辑

Set "String=AB134SSPQS"
Set "Up2Sub=%String:*AB=%"
Set "SubStr=%Up2Sub:QS="&:"%"
Echo %SubStr%

编辑2

正如您在另一个问题中给出的那样，并根据您现在更改的问题在此处添加，这是一种方法：

@Echo Off
Set "CMS_SQL=cms91_to_913.json cms913_to_9132.json cms9132_to_9133.json cms9133_to_10100.json"
Set "CMS_FROM_VERSION=cms913_"
Set "CMS_TO_VERSION=to_9133.json"
For /F "Delims=" %%A In ('Echo %%CMS_SQL:*%CMS_FROM_VERSION%^=%%'
) Do Set "SUBSTRING=%CMS_FROM_VERSION%%%A"
For /F "Delims=" %%A In ('Echo %%SUBSTRING:%CMS_TO_VERSION%^=^&:%%'
) Do Set "SUBSTRING=%%A%CMS_TO_VERSION%"
Set SUBSTRING
Pause