时间戳

首页 > 解决方案 > VBA&SQL - 从数据库中删除日期范围

sql - VBA&SQL - 从数据库中删除日期范围

问题描述

我正在尝试在我的 Access 数据库上创建一个选项，以删除两个日期之间的所有记录。

我在下面的代码似乎无法始终如一地工作。例如，如果我的数据库的日期为 01/01/18 到 01/30/18，并且我指定的范围正好是 01/01/18 到 01/30/18，那么它会起作用并删除所有数据。

但如果我指定任何其他日期范围（如 01/01 - 01/15），它将失败并且不会删除任何记录。

[交易日期] 是短文本格式，而不是日期，但所有条目都是 MM/DD/YY。除非这是问题并且没有其他选择，否则宁愿保持这种方式。

请让我知道我做错了什么或可以做得更好。先感谢您。

Dim trFrmDat As String
Dim trToDat As String
Dim dbsDelete As DAO.Database
Dim qdfToDelete As DAO.QueryDef
Dim countString As String
Dim count As Long

Set dbsDelete = CurrentDb
trFrmDat = InputBox("Trade Date To Be Deleted From [MM/DD/YY]:")
trToDat = InputBox("Trade Date To Be Deleted To [MM/DD/YY]:")
If Len(trFrmDat) <> 8 Or Len(trToDat) <> 8 Then
    MsgBox ("The correct date or answer has not been entered. Process Aborted.")
    Exit Sub
Else
    countString = "SELECT COUNT(PK_ID) FROM AR_Consolidated WHERE [Trade Date] BETWEEN " & trFrmDat & " AND " & trToDat & ""
    count = dbsDelete.OpenRecordset(countString).Fields(0).Value
    Set qdfToDelete = dbsDelete.CreateQueryDef("", "DELETE FROM AR_Consolidated WHERE [Trade Date] BETWEEN " & trFrmDat & " AND " & trToDat & "")
    qdfToDelete.Execute dbFailOnError
    MsgBox ("" & count & " records have been deleted from AR_Consolidated")
End If

编辑：

我最终使用了以下建议之一，但日期的格式仍然存在问题，因此我承认我无法将实际字段保留为短文本。我刚刚注入了一条变更线，一切正常。

    DoCmd.RunSQL "ALTER TABLE AR_Consolidated ALTER COLUMN [Trade Date] Datetime"

标签： sqlvbadatems-accessbetween

解决方案

为了在 Jet SQL 中表示日期值，您需要用 将其括起来#，这样您的 SQL 就会像这样结束：

DELETE FROM AR_Consolidated WHERE [Trade Date] BETWEEN #01/01/18# AND #01/30/18#

请注意，一般来说，将字符串与用户输入结合起来生成 SQL 语句是一个坏主意。除了与您类似的问题（在 SQL 语句中正确表示日期或其他文字）之外，您还可能遭受 SQL 注入，其中恶意用户插入额外的 SQL 语句或子句会导致您的代码失败或执行不需要的操作。例如，用户可以将以下字符串作为第二个参数传入：

01/01/18 OR 1 = 1

以及生成的 SQL 语句：

DELETE FROM AR_Consolidated WHERE [Trade Date] BETWEEN 01/01/18 AND 01/01/18 OR 1 = 1

将删除AR_Consolidated.

避免这两类问题的正确方法是使用参数化查询。

Dim sql As String
sql = _
    "PARAMETERS FromDate DATETIME, TillDate DATETIME; " & _
    "DELETE FROM AR_Consolidated " & _
    "WHERE [Trade Date] BETWEEN FromDate AND TillDate"

Dim qdfToDelete As DAO.QueryDef
Set qdfToDelete = dbsToDelete.CreateQueryDef("", sql)

qdfToDelete.Parameters("FromDate") = trFromDate 
qdfToDelete.Parameters("TillDate") = trToDate 
'You may have to convert the string values to dates first

qdfToDelete.Execute dbFailOnError

有关在针对 Jet / ACE 进行编程时如何避免 SQL 注入的全面描述，请参阅 bobby-tables.com 上的Microsoft Access和COM / 自动化页面。

推荐阅读