时间戳

首页 > 解决方案 > 调用带有可选参数的子例程时缺少实际参数

fortran - 调用带有可选参数的子例程时缺少实际参数

问题描述

我的 IDE 是集成了 Intel Fortran 编译器的 Visual Studio 2010。编译器版本为：Intel Parallel Studio XE 2011。

我不是 Fortran 经验丰富的程序员，所以我需要一些关于在派生类型的公共过程中使用可选参数的帮助。这是我的示例代码：

MODULE DERIVED_TYPE

 TYPE , PUBLIC :: SOME_TYPE

  INTEGER , PRIVATE :: V_INT

   CONTAINS

      PROCEDURE , PUBLIC :: CALL_V_INT => CALL_DATA_V_INT
      PROCEDURE , PUBLIC :: TAKE_V_INT => TAKE_DATA_V_INT

 END TYPE SOME_TYPE

 PRIVATE :: CALL_DATA_V_INT
 PRIVATE :: TAKE_DATA_V_INT

CONTAINS

! PUBLIC PROCEDURES

  SUBROUTINE CALL_DATA_V_INT( THIS , IA , IB , IC )

    CLASS( SOME_TYPE ) :: THIS
    INTEGER , INTENT( IN ) :: IA , IC
    INTEGER , INTENT( IN ) , OPTIONAL :: IB

    IF( .NOT. PRESENT( IB ) ) THEN

        THIS%V_INT = IA + IC

    ELSE

        THIS%V_INT = IA + IB + IC

    END IF

  END SUBROUTINE CALL_DATA_V_INT

  FUNCTION TAKE_DATA_V_INT ( THIS ) RESULT( RES )

    CLASS( SOME_TYPE ) :: THIS
    INTEGER :: RES

    RES = THIS%V_INT

  END FUNCTION TAKE_DATA_V_INT

END MODULE DERIVED_TYPE

PROGRAM OPTIONAL_ARG

USE , NON_INTRINSIC :: DERIVED_TYPE

IMPLICIT NONE

INTEGER :: I
INTEGER , PARAMETER :: N = 3

CLASS( SOME_TYPE ) , POINTER :: P_SOME_TYPE

TYPE( SOME_TYPE ) , DIMENSION( N ) , TARGET :: ARR_V_INT

DO I = 1 , N

   P_SOME_TYPE => ARR_V_INT( I )

   CALL P_SOME_TYPE%CALL_V_INT( I , 5 )

   WRITE( * , * ) P_SOME_TYPE%TAKE_V_INT()

END DO

END PROGRAM OPTIONAL_ARG

在编译过程结束时，我在构建窗口中收到了这种消息： Missing actual argument for argument 'ic'

这个例子有什么问题？

我还尝试将可选参数移动到参数列表中的最新位置，在这种情况下没有错误消息。

我可以获得参数列表中可选参数位置的详细说明吗？

标签： fortranintel-fortran

解决方案

您通常应该尝试将可选参数放在参数列表的末尾。当你打电话时会发生什么

  subroutine sub (a, b, c)
    real :: a, c
    real, optional :: b

  ...

  call sub(1.,2.)

是编译器必须假设1.is fora和 the 2.is for b。那么 for 的论点c就消失了。

相反，可以在缺少的可选参数之后使用命名参数

  call sub(1, c=2.)

所以在你的情况下你可以做

CALL P_SOME_TYPE%CALL_V_INT( I , IC = 5 )

如果您不想IB在参数列表的末尾有可选的。

推荐阅读