时间戳

首页 > 解决方案 > XSLT 在使用调用模板时删除空 xmlns

xslt - XSLT 在使用调用模板时删除空 xmlns

问题描述

这是我的示例 xml：

<?xml version="1.0" encoding="UTF-8"?>
<databaseChangeLog xmlns="http://www.liquibase.org/xml/ns/dbchangelog"                       
      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"                       
      xsi:schemaLocation="http://www.liquibase.org/xml/ns/dbchangelog                      
        http://www.liquibase.org/xml/ns/dbchangelog/dbchangelog-3.6.xsd                       
        http://www.liquibase.org/xml/ns/dbchangelog">
  <changeSet id="1" author="a">
    <createTable tableName="TABLE1">
      <column>
      </column>
    </createTable>
  </changeSet>
  <changeSet id="1-1" author="a">
    <createSequence sequenceName="SEQ_TABLE1" />
  </changeSet>
  <changeSet id="4" author="A">
    <createTable tableName="TABLE4">
      <column>
      </column>
    </createTable>
  </changeSet>
</databaseChangeLog>

这是我的模板：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"               xpath-default-namespace="http://www.liquibase.org/xml/ns/dbchangelog">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
  <xsl:variable name="coreTables"                  select="('TABLE1','TABLE2')"/>
  <xsl:template match="node()[not(self::*)]">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="*">
    <xsl:element name="{local-name()}">
      <xsl:apply-templates select="node()|@*"/>
    </xsl:element>
  </xsl:template>
  <xsl:template match="@*">
    <xsl:attribute name="{local-name()}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
  <xsl:template match="databaseChangeLog">
    <!-- CORE-->
    <xsl:comment>CORE TABLES</xsl:comment>
    <xsl:variable name="coreTablesVariable" select="changeSet[createTable/@tableName=$coreTables]"/>
    <xsl:apply-templates select="$coreTablesVariable"/>
    <xsl:comment>CORE SEQUENCES</xsl:comment>
    <xsl:variable name="coreSequencesVariable" select="changeSet[createSequence[starts-with(@sequenceName, 'SEQ_') and substring-after(@sequenceName, 'SEQ_') = $coreTables]]"/>
    <xsl:apply-templates select="$coreSequencesVariable"/>
    <xsl:comment>CORE INDEXES</xsl:comment>
    <xsl:variable name="coreIndexesVariable" select="changeSet[createIndex/@tableName=$coreTables]"/>
    <xsl:apply-templates select="$coreIndexesVariable"/>
    <xsl:comment>CORE FOREIGN CONSTRAINTS</xsl:comment>
    <xsl:variable name="coreForeignConstraintsVariable" select="changeSet[addForeignKeyConstraint/@baseTableName=$coreTables]"/>
    <xsl:apply-templates select="$coreForeignConstraintsVariable"/>
    <xsl:comment>CORE VIEWS</xsl:comment>
    <xsl:variable name="coreViewsVariable" select="changeSet[createView/@viewName=$coreTables]"/>
    <xsl:apply-templates select="$coreViewsVariable"/>
    <xsl:call-template name="createChangeLog">
      <xsl:with-param name="outputFile" select="'core-changelog.xml'"/>
      <xsl:with-param name="changeLogContent">
        <xsl:apply-templates select="$coreTablesVariable"/>
        <xsl:apply-templates select="$coreSequencesVariable"/>
        <xsl:apply-templates select="$coreIndexesVariable"/>
        <xsl:apply-templates select="$coreForeignConstraintsVariable"/>
        <xsl:apply-templates select="$coreViewsVariable"/>
      </xsl:with-param>
    </xsl:call-template>
  </xsl:template>
  <xsl:template name="createChangeLog">
    <xsl:param name="outputFile"/>
    <xsl:param name="changeLogContent"/>
    <xsl:result-document encoding="UTF-8" indent="true" method="xml" href="{$outputFile}">
      <databaseChangeLog xmlns="http://www.liquibase.org/xml/ns/dbchangelog"                               xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"                               xsi:schemaLocation="http://www.liquibase.org/xml/ns/dbchangelog                   http://www.liquibase.org/xml/ns/dbchangelog/dbchangelog-3.6.xsd                   http://www.liquibase.org/xml/ns/dbchangelog" logicalFilePath="TODO">
        <xsl:apply-templates select="$changeLogContent"/>
      </databaseChangeLog>
    </xsl:result-document>
  </xsl:template>
</xsl:transform>

问题是当我使用createChangeLog模板调用创建输出文件时，文件中的输出元素<changeSet>具有空xmlns=""属性。请问我怎样才能删除它？或者，如果有办法如何<databaseChangeLog使用它的名称空间定义 xml 标头，然后告诉 call-template 使用它，它可能会有所帮助（但我不知道它是否像这样工作）。

我正在使用 xslt 2.0 和 saxon 9.8he

标签： xsltsaxon

解决方案

您有一个从元素中删除命名空间的模板

<xsl:template match="*">
  <xsl:element name="{local-name()}">
    <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
</xsl:template>

这意味着，当您像这样设置changeLogContent参数时...

  <xsl:with-param name="changeLogContent">
    <xsl:apply-templates select="$coreTablesVariable"/>
    <xsl:apply-templates select="$coreSequencesVariable"/>
    <xsl:apply-templates select="$coreIndexesVariable"/>
    <xsl:apply-templates select="$coreForeignConstraintsVariable"/>
    <xsl:apply-templates select="$coreViewsVariable"/>
  </xsl:with-param>

...它将使用此模板，因此被设置为没有命名空间的节点副本。

首先，你应该做的是改变xsl:with-param这个，选择原始节点，而不是创建副本......

  <xsl:with-param name="changeLogContent" select="$coreTablesVariable,$coreSequencesVariable,$coreIndexesVariable,$coreForeignConstraintsVariable,$coreViewsVariable"/>

然后，在 中createChangeLog，如果您真的想复制节点而不进行更改，请使用xsl:copy-of而不是xsl:apply-templates( 因为xsl:apply-templates只会再次匹配命名空间删除模板。

<xsl:copy-of select="$changeLogContent"/>

试试这两个模板

<xsl:template match="databaseChangeLog">
    <!-- CORE-->
    <xsl:comment>CORE TABLES</xsl:comment>
    <xsl:variable name="coreTablesVariable" select="changeSet[createTable/@tableName=$coreTables]"/>
    <xsl:apply-templates select="$coreTablesVariable"/>
    <xsl:comment>CORE SEQUENCES</xsl:comment>
    <xsl:variable name="coreSequencesVariable" select="changeSet[createSequence[starts-with(@sequenceName, 'SEQ_') and substring-after(@sequenceName, 'SEQ_') = $coreTables]]"/>
    <xsl:apply-templates select="$coreSequencesVariable"/>
    <xsl:comment>CORE INDEXES</xsl:comment>
    <xsl:variable name="coreIndexesVariable" select="changeSet[createIndex/@tableName=$coreTables]"/>
    <xsl:apply-templates select="$coreIndexesVariable"/>
    <xsl:comment>CORE FOREIGN CONSTRAINTS</xsl:comment>
    <xsl:variable name="coreForeignConstraintsVariable" select="changeSet[addForeignKeyConstraint/@baseTableName=$coreTables]"/>
    <xsl:apply-templates select="$coreForeignConstraintsVariable"/>
    <xsl:comment>CORE VIEWS</xsl:comment>
    <xsl:variable name="coreViewsVariable" select="changeSet[createView/@viewName=$coreTables]"/>
    <xsl:apply-templates select="$coreViewsVariable"/>

    <xsl:call-template name="createChangeLog">
      <xsl:with-param name="outputFile" select="'core-changelog.xml'"/>
      <xsl:with-param name="changeLogContent" select="$coreTablesVariable,$coreSequencesVariable,$coreIndexesVariable,$coreForeignConstraintsVariable,$coreViewsVariable"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="createChangeLog">
    <xsl:param name="outputFile"/>
    <xsl:param name="changeLogContent"/>
    <xsl:result-document encoding="UTF-8" indent="true" method="xml" href="{$outputFile}">
      <databaseChangeLog xmlns="http://www.liquibase.org/xml/ns/dbchangelog"                               xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"                               xsi:schemaLocation="http://www.liquibase.org/xml/ns/dbchangelog                   http://www.liquibase.org/xml/ns/dbchangelog/dbchangelog-3.6.xsd                   http://www.liquibase.org/xml/ns/dbchangelog" logicalFilePath="TODO">
        <xsl:copy-of select="$changeLogContent"/>
      </databaseChangeLog>
    </xsl:result-document>
</xsl:template>

推荐阅读