时间戳

首页 > 解决方案 > vba - 循环内的循环冻结excel

arrays - vba - 循环内的循环冻结excel

问题描述

我正在尝试创建一个循环来通过一个数组（47193, 4）和一个名为攻击（41892,1）的数组 2。这里的想法是攻击数组具有从工作表中按顺序排列的值，我稍后将这些值添加到下一列，这就是我将值添加到第三个数组的原因。因此，循环将逐一遍历攻击数组中的值，同时遍历 arr 数组以查找公共数据。我尝试将值直接复制到工作表，但 excel 冻结了很多。现在通过这种方式，excel此时仍然冻结。有什么问题吗？

Dim arr3() As Variant
Dim dee As Long

ReDim arr3(UBound(attacks, 1), 1)

For k = 0 To UBound(attacks, 1)
   j = 0

   For j = 0 To UBound(arr, 1)

       If attacks(k, 0) = arr(j, 0) And attacks(k, 1) = arr(j, 2) Then
           arr3(dee, 0) = attacks(k, 0)
           arr3(dee, 1) = attacks(k, 1)
           de = dee + 1
       End If

    Next j

Next k

标签： arraysvbaexcel

解决方案

这是一些显示如何使用字典的代码：

Sub Tester()

    Const SZ As Long = 10000 'size of test arrays

    Dim arr1(1 To SZ, 1 To 2)
    Dim arr2(1 To SZ, 1 To 2)
    Dim arr3(1 To SZ, 1 To 2) '<<matches go here
    Dim n As Long, m As Long, i As Long, t, dict, k

    t = Timer
    'fill test arrays with random data
    For n = 1 To SZ
        arr1(n, 1) = CLng(Rnd * 200)
        arr1(n, 2) = CLng(Rnd * 200)
        arr2(n, 1) = CLng(Rnd * 200)
        arr2(n, 2) = CLng(Rnd * 200)
    Next n

    Debug.Print "Filled test arrays", Timer - t
    t = Timer
    'test the nested loop approach
    For n = 1 To SZ
    For m = 1 To SZ
        If arr1(n, 1) = arr2(m, 1) And arr1(n, 2) = arr2(m, 2) Then
            i = i + 1
            arr3(i, 1) = arr1(n, 1)
            arr3(i, 2) = arr1(n, 2)
        End If
    Next m
    Next n

    Debug.Print "Finished nested loop", Timer - t, i & " matches"
    t = Timer

    'create a lookup using a dictionary
    Set dict = CreateObject("scripting.dictionary")
    For n = 1 To SZ
        k = arr1(n, 1) & "|" & arr1(n, 2)
        dict(k) = dict(k) + 1
    Next n
    Debug.Print "Filled dictionary", Timer - t
    t = Timer

    i = 0
    Erase arr3

    'Perform the match against arr2 using the dictionary
    For m = 1 To SZ
        k = arr2(m, 1) & "|" & arr2(m, 2)
        If dict.exists(k) Then
            i = i + 1
            arr3(i, 1) = arr2(m, 1)
            arr3(i, 2) = arr2(m, 2)
        End If
    Next m

    Debug.Print "Finished dictionary loop", Timer - t, i & " matches"

End Sub

输出：

Filled test arrays           0 
Finished nested loop         9.101563     2452 matches
Filled dictionary            0.03125 
Finished dictionary loop     0.0078125    2177 matches

请注意，匹配数略有不同 - 嵌套循环捕获重复匹配，但 Dictionary 仅计算唯一匹配。您可能需要根据您的用例进行调整。

推荐阅读