arrays - 为什么 AS3 在 for 循环中创建新实例？

Question

到目前为止，我从 actionscript 中看到的最奇怪的行为，我已经使用 AS 工作了 10 多年。

var clip1:MovieCip = new MovieClip();  
var clip2:MovieCip = new MovieClip();  
var clip3:MovieCip = new MovieClip();    
var clip;

var myarray:Array = new Array(clip1, clip2, clip3);    

for each (clip in myarray)
{ removeChild(clip);
  clip = new mc();
  trace(clip.name); }

看起来很简单吧？出于某种原因，flash 正在将实例名称更改为 instanceX，其中 X 是一些随机分配的数字，我不再能够通过它们分配的名称调用剪辑，例如，如果我尝试...

 clip1.x = 300;

flash 不会抛出错误，但clip1.x 不会移动到 300。我已经为此工作了几个小时，看起来movieclips 实际上仍然存在，但flash 已经创建了新的movieclips！请帮忙

标签： arraysactionscript-3movieclip

Answer 1

您似乎不了解成员名称和实例名称之间的区别。我假设您在时间轴上编写代码，这意味着您在由该时间轴表示的MovieClip对象内部进行操作（可能是主时间轴，在这种情况下，您在root内部进行操作）。

Member是一个 OOP 词，表示对象的字段（普通数据和对象引用）和方法（绑定函数）。您可以使用点表示法或方括号表示法来访问成员：

this['a'] = 10;
trace(this.a); // output: 10

当您在时间轴上编写代码时，当您声明变量或函数时，您实际上是在声明当前MovieClip的字段和方法（分别） ：

var a:int = 10;

trace(a);         // output: 10
trace(this.a);    // output: 10
trace(this['a']); // output: 10

请记住，在函数体内声明的变量不是对象成员，而是局部函数变量：

function A():void
{
    var a:int = 999;

    trace(a);      // output: 999
    trace(this.a); // output: undefined
}

实例名称是“名称”名称下的DisplayObject类的类成员。

trace(name);         // output: instance123
trace(this.name);    // output: instance123
trace(this['name']); // output: instance123

令人困惑的部分是 Flash 自动将预先设计的事物声明为对象成员，其成员名称与实例名称相同。因此，如果您放置一些实例名称为MC1的MovieClip，您可以按以下方式对其进行寻址：

trace(MC1);         // output: [object MovieCip]
trace(this.MC1);    // output: [object MovieCip]
trace(this['MC1']); // output: [object MovieCip]
trace(getChildByName("MC1"));      // output: [object MovieCip]
trace(this.getChildByName("MC1")); // output: [object MovieCip]

您可以在File > Publish Settings > AS3 Settings > Auto-declare Stage Instances处关闭自动声明选项。如果这样做，输出将有所不同：

trace(MC1);         // output: undefined
trace(this.MC1);    // output: undefined
trace(this['MC1']); // output: undefined
trace(getChildByName("MC1"));      // output: [object MovieCip]
trace(this.getChildByName("MC1")); // output: [object MovieCip]

此外，自动声明的东西有效，让我再次强调一下，只有预先设计的内容。如果您创建任何东西的新实例并将它们addChild(...)它们添加到容器中，它不会自动将它们的引用添加为容器 OOP 成员。

然后，它如何影响您的问题。

你打电话给clip1.x = 300; 并且没有错误。当然没有。clip1成员仍然持有对最初声明和实例化的var clip1:MovieCip = new MovieClip();的引用。而且您从未将任何内容重新分配给该成员。因此，您处理了未附加到任何东西的有效MovieClip，但这对 AS3 或 Flash 平台无关紧要：您正在对有效对象执行有效操作。

如果你想处理新创建的实例，你应该通过你放置它们的数组，或者通过精心组织的实例名称，或者通过将它们的引用分配给各个成员名称的成员来完成：

var clip0:MovieCip = new MovieClip;
var clip1:MovieCip = new MovieClip;
var clip2:MovieCip = new MovieClip;
var clip3:MovieCip = new MovieClip;

var myarray:Array = new Array(clip0, clip1, clip2, clip3);

for (var i:int = 0; i < myarray.length; i++)
{
    // You better call the class MC, because lowercase
    // class name looks like a variable name.
    var aClip:MC = new MC;

    // Give it a proper instance name.
    aClip.name = "clip" + i;

    // Assign it as a member of current object.
    this["clip" + i] = aClip;

    // Put it to designated place into the Array.
    myarray[i] = aClip;
}

现在你可以用任何你想要的方式来解决它：

trace(clip1);         // output: [object MC]
trace(this.clip1);    // output: [object MC]
trace(this['clip1']); // output: [object MC]
trace(myarray[1]);    // output: [object MC]
trace(getChildByName("clip1"));      // output: [object MC]
trace(this.getChildByName("clip1")); // output: [object MC]