时间戳

首页 > 解决方案 > 如何创建一个包含普通标准错误和稳健标准错误的表格？

stata - 如何创建一个包含普通标准错误和稳健标准错误的表格？

问题描述

我经常在出版物中看到回归表，其中报告了普通标准误差（在括号中），以及在普通标准误差下方的稳健标准误差（在括号中）。这些表格还包括括号/括号旁边的随附星号，表示统计显着性。

创建这样的回归报告最明智的方法是什么？

到目前为止，我一直estout在Stata中使用该包。对于给定的模型，我可以有一个具有普通标准误差的列，而另一个具有稳健标准误差的列。

例如，使用estout，我可以执行以下操作：

eststo: qui reg ROE duality
eststo: qui reg ROE duality, vce(cluster firm)

esttab b(%9.3fc) ///                     
       se(%9.3fc) ///
       star (* 0.5 ** 0.25)

上述代码片段产生：

--------------------------------------------
                (1)             (2)   
                ROE             ROE   
--------------------------------------------
duality       -8.090**        -8.090*   
              (6.585)         (7.067)   
--------------------------------------------
N               647             647   
--------------------------------------------

但是，该表浪费了列空间，因为两列的点估计值相同，唯一的区别是来自不同方差-协方差估计量的标准误差。

我更希望有一张像下面这样的表格：

 ------------------------
                (1)      
                ROE      
-------------------------
duality       -8.090     
              (6.585)** 
              [7.067]*   
-------------------------
N               647      
-------------------------

请注意，0.5 和 0.25 的统计显着性指示仅用于说明此处，当然不反映惯例。

标签： stata

解决方案

您只需要手动添加稳健的标准错误：

sysuse auto, clear
eststo clear

quietly regress price weight mpg, vce(robust)
matrix regtab = r(table)
matrix regtab = regtab[2,1...]
matrix rbse = regtab

eststo: quietly regress price weight mpg

estadd matrix rbse = rbse
esttab, cells(b se rbse)

-------------------------
                      (1)
                    price
                b/se/rbse
-------------------------
weight           1.746559
                 .6413538
                  .777837
mpg             -49.51222
                 86.15604
                  95.8074
_cons            1946.069
                  3597.05
                 4213.793
-------------------------
N                      74
-------------------------

将其格式化为您的规格需要使用相关选项：

esttab , cells("b(fmt(a3) star)" "se(fmt(a2) par)" "rbse(fmt(a2) par([ ]))") ///
star(* 0.5 ** 0.25)  addnote("Robust SE in brackets" "* p<0.5, ** p<0.25") ///
nonumbers

---------------------------
                    price  
                b/se/rbse  
---------------------------
weight              1.747**
                   (0.64)  
                   [0.78]  
mpg                -49.51  
                   (86.2)  
                   [95.8]  
_cons              1946.1  
                 (3597.0)  
                 [4213.8]  
---------------------------
N                      74  
---------------------------
Robust SE in brackets
* p<0.5, ** p<0.25

推荐阅读