时间戳

首页 > 解决方案 > 在 vim 中获取文档的实时字数

vim - 在 vim 中获取文档的实时字数

问题描述

我希望 vim 在状态栏中显示文档总字数（显示当前行和字符数）。我在 SO 上遇到过类似的问题，并尝试了这里和这里提到的所有建议——但它们都没有对我的状态栏产生任何影响。

为了明确列举一些，我尝试将以下任何内容粘贴到我的~/.vimrc（并且 ofc 随后重新启动 vim）中：

function! CountNonEmpty()
    let l = 1
    let char_count = 0
    while l <= line("$")
        if len(substitute(getline(l), '\s', '', 'g')) > 3   
            let char_count += 1 
        endif
        let l += 1
    endwhile
    return char_count
endfunction

function WordCount()
  let s:old_status = v:statusmsg
  exe "silent normal g\<c-g>"
  let s:word_count = str2nr(split(v:statusmsg)[11])
  let v:statusmsg = s:old_status
  return s:word_count
endfunction  

" If buffer modified, update any 'Last modified: ' in the first 20 lines.
" 'Last modified: ' can have up to 10 characters before (they are retained).
" Restores cursor and window position using save_cursor variable.
function! LastModified()
  if &modified
    let save_cursor = getpos(".")
    let n = min([15, line("$")])
    keepjumps exe '1,' . n . 's#^\(.\{,10}LOC:\).*#\1' .
          \ ' ' . CountNonEmpty() . '#e'
    keepjumps exe '1,' . n . 's#^\(.\{,10}Word Count:\).*#\1' .
          \ ' ' . WordCount() . '#e'
    call histdel('search', -1)
    call setpos('.', save_cursor)
  endif
endfun

或者

function WordCount()
  let s:old_status = v:statusmsg
  exe "silent normal g\<c-g>"
  let s:word_count = str2nr(split(v:statusmsg)[11])
  let v:statusmsg = s:old_status
  return s:word_count
endfunction
set statusline=wc:%{WordCount()}

或者

function! WordCount()
   let s:old_status = v:statusmsg
   let position = getpos(".")
   exe ":silent normal g\<c-g>"
   let stat = v:statusmsg
   let s:word_count = 0
   if stat != '--No lines in buffer--'
     let s:word_count = str2nr(split(v:statusmsg)[11])
     let v:statusmsg = s:old_status
   end
   call setpos('.', position)
   return s:word_count 
endfunction
set statusline=wc:%{WordCount()}

或者

let g:word_count="<unknown>"
fun! WordCount()
    return g:word_count
endfun
fun! UpdateWordCount()
    let s = system("wc -w ".expand("%p"))
    let parts = split(s, ' ')
    if len(parts) > 1
        let g:word_count = parts[0]
    endif
endfun

augroup WordCounter
    au! CursorHold * call UpdateWordCount()
    au! CursorHoldI * call UpdateWordCount()
augroup END

" how eager are you? (default is 4000 ms)
set updatetime=500

" modify as you please...
set statusline=%{WordCount()}\ words

或者更多。正如我所说，没有效果。没有错误消息，没有视觉上可察觉的变化。我想可能有一个我遗漏的常见问题，但它是什么？

标签： vimword-count

解决方案

假设您的状态行已启用 ( set laststatus=2)，则如下：

set statusline+=%{wordcount().words}\ words

在 Vim 7.4.1042 及更高版本中完全符合您的要求：

厕所

见:help wordcount()。

如果你绝对需要向后兼容，以下内容几乎可以保证在 Vim 7.x 中工作，并且可能也可以在早期版本中工作：

function! WC()
    return len(split(join(getline(1,'$'), ' '), '\s\+'))
endfunction
set statusline+=%{WC()}\ words

不过，这些旧线程中的一些答案可能会更快或更智能。

您对那些旧线程中的这些功能的评论不会改变您的状态行，这让我想知道问题是在所有这些旧答案中还是在其他地方。也许……你一开始就没有状态栏？

推荐阅读