neo4j - 使用 Neo4j/Cypher 查找选定子图的所有叶子

Question

初始情况

• 具有树状结构的大型 Neo4j 3.4.6 图（10 层深，1000 万个节点）。
• 毫无例外，所有节点都相互连接。节点和关系在每种情况下都属于同一类型。
• 正好是一个中心根节点。
• 简化和简化的示例：

图形表示

CREATE (Root:CustomType {name: 'Root'})
CREATE (NodeA:CustomType {name: 'NodeA'})
CREATE (NodeB:CustomType {name: 'NodeB'})
CREATE (NodeC:CustomType {name: 'NodeC'})
CREATE (NodeD:CustomType {name: 'NodeD'})
CREATE (NodeE:CustomType {name: 'NodeE'})
CREATE (NodeF:CustomType {name: 'NodeF'})
CREATE (NodeG:CustomType {name: 'NodeG'})
CREATE (NodeH:CustomType {name: 'NodeH'})
CREATE (NodeI:CustomType {name: 'NodeI'})
CREATE (NodeJ:CustomType {name: 'NodeJ'})
CREATE (NodeK:CustomType {name: 'NodeK'})
CREATE (NodeL:CustomType {name: 'NodeL'})
CREATE (NodeM:CustomType {name: 'NodeM'})
CREATE (NodeN:CustomType {name: 'NodeN'})
CREATE (NodeO:CustomType {name: 'NodeO'})
CREATE (NodeP:CustomType {name: 'NodeP'})
CREATE (NodeQ:CustomType {name: 'NodeQ'})

CREATE
  (Root)-[:CONTAINS]->(NodeA),
  (Root)-[:CONTAINS]->(NodeB),
  (Root)-[:CONTAINS]->(NodeC),
  (NodeA)-[:CONTAINS]->(NodeD),
  (NodeA)-[:CONTAINS]->(NodeE),
  (NodeA)-[:CONTAINS]->(NodeF),
  (NodeE)-[:CONTAINS]->(NodeG),
  (NodeE)-[:CONTAINS]->(NodeH),
  (NodeF)-[:CONTAINS]->(NodeI),
  (NodeF)-[:CONTAINS]->(NodeJ),
  (NodeF)-[:CONTAINS]->(NodeK),
  (NodeI)-[:CONTAINS]->(NodeL),
  (NodeI)-[:CONTAINS]->(NodeM),
  (NodeJ)-[:CONTAINS]->(NodeN),
  (NodeK)-[:CONTAINS]->(NodeO),
  (NodeK)-[:CONTAINS]->(NodeP),
  (NodeM)-[:CONTAINS]->(NodeQ);

待解决的挑战

• 通过 MATCH-WITH-UNWIND Cypher 查询，我可以成功选择子树并将其绑定到路径。假设子树跨越节点 A、E、F、I 和 J。
• 基于这条路径，我现在需要子树的所有叶子，而不是完整的树。

.

MATCH
  path = (:CustomType {name:'NodeA'})-[:CONTAINS*]->(:CustomType {name:'NodeJ'}) /* simplified */
WITH
  nodes(path) as selectedPath
  /* here: necessary magic to identify the leaf nodes of the subtree */
RETURN
  leafNode;

• 除其他外，我尝试用一​​种WHERE NOT(node-->())方法解决需求，但意识到这仅适用于完整树的叶子。不幸的是，我无法说服该WHERE NOT(node-->())子句尊重选定的子树边界。
• 那么，如何使用 Cypher 和 Neo4j 找到选定子图的所有叶子？你能给我一个建议如何解决这个挑战吗？非常感谢您为我指明了正确的方向！

标签： neo4jcypher

Answer 1

您正确地注意到没有子节点的检查节点仅适用于整个树。所以你需要遍历子树中的所有关系，找到子树的这样一个节点作为关系的结束，而不是关系的开始：

MATCH
  path = (:CustomType {name:'NodeA'})-[:CONTAINS*]->(:CustomType {name:'NodeJ'})
UNWIND relationShips(path) AS r
WITH collect(DISTINCT endNode(r))   AS endNodes, 
     collect(DISTINCT startNode(r)) AS startNodes
UNWIND endNodes AS leaf
WITH leaf WHERE NOT leaf IN startNodes
RETURN leaf