时间戳

首页 > 解决方案 > Perl 在不同的命名空间中导入包

perl - Perl 在不同的命名空间中导入包

问题描述

是否可以use在不同的命名空间中导入（）一个 perl 模块？

假设我有一个模块A（没有导出方法的 XS 模块@EXPORT是空的）并且我无法更改模块。

这个模块有一个方法A::open

目前我可以通过调用在我的主程序（主程序包）中使用该模块A::open我想将该模块放在我的内部package main以便我可以直接调用open

我尝试手动将每个键推%A::入%main::，但没有按预期工作。

我知道实现我想要的唯一方法是package A;在我的主程序中使用，有效地将我的程序包main从A. 我对此并不满意。我真的很想把我的程序放在主包中。

有什么方法可以实现这一点并且仍然将我的程序保留在主包中？

题外话：是的，我知道通常你不想将所有东西都导入你的命名空间，但是这个模块被我们广泛使用，我们不想输入 A:: （实际的模块名称更长，这不会使情况更好）在数百或数千个电话面前

标签： perlimportnamespaces

解决方案

这是那些“不可能”的情况之一，其中明确的解决方案——重做该模块——是不受限制的。

但是，您可以将该包的子名称从其符号表中别名为main. 比粗鲁更糟糕的是，这会带来一个小故障：它会捕获该包本身以任何方式导入的所有名称。然而，由于这个包是一个固定的数量，你可以建立这个列表（甚至硬编码它）。就这一次吧？

主要的

use warnings;
use strict;
use feature 'say';

use OffLimits;

GET_SUBS: {
    # The list of names to be excluded
    my $re_exclude = qr/^(?:BEGIN|import)$/;  # ...
    my @subs = grep { !/$re_exclude/ } sort keys %OffLimits::;
    no strict 'refs';
    for my $sub_name (@subs) {
        *{ $sub_name } = \&{ 'OffLimits::' . $sub_name };
    }   
};

my $name = name('name() called from ' . __PACKAGE__);
my $id   = id('id() called from ' . __PACKAGE__);

say "name() returned: $name";
say "id()   returned: $id";

和OffLimits.pm

package OffLimits;    
use warnings;
use strict;

sub name { return "In " .  __PACKAGE__ . ": @_" }
sub id   { return "In " .  __PACKAGE__ . ": @_" }

1;

它打印

name() 返回：在 OffLimits 中：从 main 调用 name()
id() 返回：在 OffLimits 中：从 main 调用的 id()

您可能需要在一个BEGIN块中使用该代码，具体取决于其他详细信息。

另一种选择当然是硬编码要“导出”的潜艇（在 中@subs）。鉴于模块在实践中是不可变的，这个选项是合理且更可靠的。

这也可以包装在一个模块中，以便您进行正常的、选择性的、导入。

WrapOffLimits.pm

package WrapOffLimits;
use warnings;
use strict;

use OffLimits;

use Exporter qw(import);

our @sub_names;
our @EXPORT_OK   = @sub_names;
our %EXPORT_TAGS = (all => \@sub_names);

BEGIN { 
    # Or supply a hard-coded list of all module's subs in @sub_names
    my $re_exclude = qr/^(?:BEGIN|import)$/;  # ...
    @sub_names = grep { !/$re_exclude/ } sort keys %OffLimits::;

    no strict 'refs';
    for my $sub_name (@sub_names) {
        *{ $sub_name } = \&{ 'OffLimits::' . $sub_name };
    }   
};
1;

现在在调用者中你可以只导入一些潜艇

use WrapOffLimits qw(name);

或全部

use WrapOffLimits qw(:all);

否则与上述相同的 main 进行测试。

模块名称是硬编码的，应该没问题，因为这仅适用于该模块。

以下主要是为了完整性而添加的。

可以通过编写自己的import子程序将模块名称传递给包装器，然后使用它。导入列表也可以传递，但代价是use语句的界面很尴尬。

它沿着

package WrapModule;
use warnings;
use strict;

use OffLimits;

use Exporter qw();  # will need our own import 

our ($mod_name, @sub_names);

our @EXPORT_OK   = @sub_names;
our %EXPORT_TAGS = (all => \@sub_names);

sub import {
    my $mod_name = splice @_, 1, 1;  # remove mod name from @_ for goto

    my $re_exclude = qr/^(?:BEGIN|import)$/;  # etc

    no strict 'refs';
    @sub_names = grep { !/$re_exclude/ } sort keys %{ $mod_name . '::'};    
    for my $sub_name (@sub_names) {    
        *{ $sub_name } = \&{ $mod_name . '::' . $sub_name };
    }   

    push @EXPORT_OK, @sub_names;

    goto &Exporter::import;
}
1;

可以用作什么

use WrapModule qw(OffLimits name id);  # or (OffLimits :all)

或者，通过分解列表来提醒用户不寻常的界面

use WrapModule 'OffLimits', qw(name id);

当与上面的 main 一起使用时，它会打印相同的输出。

该use语句最终使用模块中定义的import sub，它通过写入调用者的符号表来导出符号。（如果没有import写子，那么很好地使用Exporter'import方法，这就是通常的做法。）

这样我们就可以解包参数并在use调用时提供模块名称。现在我们必须push手动提供导入列表，@EXPORT_OK因为这不能处于BEGIN阶段。最后，通过gotoExporter::import的（良好形式）替换 sub以完成工作。

推荐阅读