parallel-processing - Chapel 中的共享内存 n 体模拟
问题描述
我正在尝试重新实现 Peter Pacheco 的并行编程简介第 6.1.6 章中介绍的 n 体模拟的共享内存实现。在那一章中,它是使用 OpenMP 实现的。
这是我使用OpenMP的并行实现。这是一个使用Chapel的串行实现。我在使用 Chapel 实现共享内存并行实现时遇到问题。由于无法在forall
循环中获取线程的等级,因此我不能使用与 OpenMP 实现中相同的方法。我将不得不使用coforall
循环、创建任务并手动分配迭代。这似乎不切实际,并表明有一种更优雅的方法可以在 Chapel 内解决这个问题。
我正在寻找有关如何使用 Chapel 提供的工具更好地解决此问题的指导和建议。
解决方案
我的建议是在你的 forall 循环中使用 (+)减少意图forces
,这将为每个任务提供其自己的私有副本,forces
然后在任务完成时(总和)将它们的单独副本减少回原始forces
变量。这可以通过将以下 with 子句附加到您的 forall 循环来完成:
forall q in 0..#n_bodies with (+ reduce forces) {
在这里,我寻找其他方法使代码更优雅,并建议从二维数组更改为数组数组来解决这个问题,以便折叠一堆类似的代码语句 x, y , z 组件归结为单个语句。我还使用了您的pDomain
变量并创建了一个类型别名,[0..#3] real
以消除代码中的一些冗余。哦,我删除了and模块的use
s,因为它们在 Chapel 程序中自动使用。Math
IO
这就是我离开的地方:
config const filename = "input.txt";
config const iterations = 100;
config const out_filename = "out.txt";
const X = 0;
const Y = 1;
const Z = 2;
const G = 6.67e-11;
config const dt = 0.1;
// Read input file, initialize bodies
var f = open(filename, iomode.r);
var reader = f.reader();
var n_bodies = reader.read(int);
const pDomain = {0..#n_bodies};
type vec3 = [0..#3] real;
var forces: [pDomain] vec3;
var velocities: [pDomain] vec3;
var positions: [pDomain] vec3;
var masses: [pDomain] real;
for i in pDomain {
positions[i] = reader.read(vec3);
velocities[i] = reader.read(vec3);
masses[i] = reader.read(real);
}
f.close();
reader.close();
for i in 0..#iterations {
// Reset forces
forces = [0.0, 0.0, 0.0];
forall q in pDomain with (+ reduce forces) {
for k in pDomain {
if k <= q {
continue;
}
var diff = positions[q] - positions[k];
var dist = sqrt(diff[X]**2 + diff[Y]**2 + diff[Z]**2);
var dist_cubed = dist**3;
var tmp = -G * masses[q] * masses[k] / dist_cubed;
var force_qk = tmp * diff;
forces[q] += force_qk;
forces[k] -= force_qk;
}
}
forall q in pDomain {
positions[q] += dt * velocities[q];
velocities[q] += dt / masses[q] * forces[q];
}
}
var outf = open(out_filename, iomode.cw);
var writer = outf.writer();
for q in pDomain {
writer.writeln("%er %er %er %er %er %er".format(positions[q][X], positions[q][Y], positions[q][Z], velocities[q][X], velocities[q][Y], velocities[q][Z]));
}
writer.close();
outf.close();
您可以考虑进行的另一项更改是用以下整个数组语句替换更新位置和速度的 forall 循环:
positions += dt * velocities;
velocities += dt / masses * forces;
其中主要的权衡是 forall 将使用单个并行循环以融合的方式实现语句,而整个数组语句不会(至少在当前版本的 1.18 编译器中)。
推荐阅读
- excel - Excel VBA:由于未准备好,在保存期间保护/取消保护宏中断
- asp.net-mvc - 从 Azure Web 应用上传到 Azure Blob 存储时出现 IO 错误
- c# - 使用 C# 泛型的错误拳击警告?
- javascript - JS。如何替换变量内的 html() 对象中的文本?
- asp.net - Sitecore Xpath 比较两个字段
- regex - How to handle a tilde / swung dash (~) in a regular expression in order to exclude temporary MS Office files?
- r - 正则表达式 - 捕获重复组,不包括周围部分匹配的内容
- javascript - jquery 在尝试从用户获取图像以通过 ajax 将其发送到控制器时抛出未捕获的 TypeError
- php - 使用 SMTP/PHP 的间歇性联系表单失败
- ms-access - MS Access 2016 找不到我的功能/模块