时间戳

首页 > 解决方案 > 使用批处理脚本组织文件

windows - 使用批处理脚本组织文件

问题描述

我需要以某种方式将所有文件从源文件夹（包括子文件夹）复制到目标文件夹，并将子文件夹名称作为文件名。

在 Windows 上使用批处理文件。

例子：

sourceFolder\packed1.bin
sourceFolder\data1\packed1.bin
sourceFolder\data1\packed2.bin
sourceFolder\data1\zz\packed1.bin
sourceFolder\data1\aa\packed1.bin
sourceFolder\data1\aa\22\packed1.bin

应该变成...

destinationFolder\packed1.bin
destinationFolder\data1-packed1.bin
destinationFolder\data1-packed2.bin
destinationFolder\data1-zz-packed1.bin
destinationFolder\data1-aa-packed1.bin
destinationFolder\data1-aa-22-packed1.bin

我尝试使用goto，但我无法跟踪我所在的目录然后返回它。

@echo off
setlocal EnableDelayedExpansion

set mypath=%cd%
set "_orig=%mypath%\datafolder"
set "_origCurr=%_orig%"
set "_dest=%mypath%\untree\"

set procDirs
set /a procDirsL=0
set currDirS=""
set /a isProc=0

:gofolders
for /d %%D in ("%_dest%\*.*") do (
set currDirS=%currDirS%\%%D
set procDirs[!procDirsL!]

set /a procDirsL=!procDirsL!+1


goto gofolders
)

:dofiles
for /f %%F in ("%_dest%\*.*") do (

)
goto gofolders

标签： windowsbatch-filebatch-rename

解决方案

@echo off
setlocal

rem Set target and destination paths.
set "target=%cd%\sourceFolder"
set "dest=%cd%\destinationFolder"

rem Make dest dir if needed.
if not exist "%dest%" md "%dest%"

rem Recurse target and get filepath of .bin files.
for /r "%target%" %%A in (*.bin) do call :moveToDest %%A
exit /b

:moveToDest
setlocal
set "oldname=%~1"

rem Remove target from the filepath.
call set "newname=%%oldname:%target%=%%"
if not defined newname (
    >&2 echo target is undefined
    exit /b 1
)

rem Remove leading \.
if "%newname:~,1%" == "\" set "newname=%newname:~1%"

rem Replace \ with -.
set "newname=%newname:\=-%"

rem Copy new named file to dest.
copy "%oldname%" "%dest%\%newname%" >nul
if errorlevel 1 (
    >&2 echo Failed to copy "%oldname%" to "%dest%\%newname%"
    exit /b 1
)
exit /b

设置target和dest执行之前。

由于目标文件被重命名并复制到没有子文件夹结构的目标，因此在开始时只完成一次目标文件夹。

目标文件夹通过for循环递归并获取.bin文件的所有完整路径。使用每个文件:moveToDest的完整路径的参数调用标签。.bin

在标签:moveToDest中，传递的参数设置为oldname。如果需要，删除目标路径和前导反斜杠。这会将 oldname 设置为目标路径的相对路径。反斜杠替换为破折号以创建用于复制的文件名。.bin使用新文件名将文件从copy目标复制到目标。

推荐阅读