时间戳

首页 > 解决方案 > 最大值匹配商函数

maxima - 最大值匹配商函数

问题描述

我们有一个在线平台，我们在后端使用 maxima 对学生给出的答案提供反馈。

假设多项式长除法的解是以下函数：

sol: 3+(2+4*x)/(3*x^2+2*x+8);

假设学生给出了答案：

ans: 3 +(3-5*x)/(3x^2+2*x+8)

然后，我们希望提供反馈。

您的答案确实是以下形式：

在此处输入图像描述

常数 s 是正确的，但您没有选择正确的线性函数 r(x)。

我尝试通过以下方式实现此反馈：

ans: 3 +(3-5*x)/(3x^2+2*x+8);
remvalue(a,b,c,d);
matchdeclare([a,b,c,d], constantp);
defmatch(match, d+ (a*x+b)/(3*x^2+2*x+8));
match(ans);

但是， defmatch 似乎无法匹配这个。有没有其他函数可以用来匹配这样的商函数？

它确实适用于更简单的场景：

ans: (3-5*x)/(3*x^2+2*x+8); 
remvalue(a,b,c);
matchdeclare([a,b,c], constantp);     
defmatch(match, (a*x+b)/(3*x^2+2*x+8));     
match(ans);

标签： maxima

解决方案

如果问题都是多项式除法，也许您可​​以使用divide返回商和余数的函数，然后验证学生的输入是否与商+余数/除数相同。

至于匹配商 + 余数/除数，defmatch可能不够强大，因为它主要（尽管不完全）寻找形式匹配，并且在许多情况下，它无法检测等价但形式不同的表达式。

让我想想如何为这个问题实现一个匹配函数。也许其他人也有建议。

编辑：这是匹配此类表达式的一种方法。我将多项式的比率与其他项分开。如果有一个比率项，而所有其他项都是多项式，则匹配您想要的模式。

我已经利用了至少一个晦涩但有用甚至易于理解的"+"表达式匹配特性。由于"+"是可交换的，模式匹配器会扫描所有与第一个尝试的谓词匹配的参数，然后用第二个进行扫描，如果有两个以上的预测，则如此。如果任何模式匹配变量被声明为 match all，它将匹配所有参数并且没有剩余。模式变量将以相反的顺序尝试，因此aa将最后处理。其效果是将"+"表达式划分为与陈述的谓词匹配的术语和其他所有内容的包罗万象。这是在%i7.

(%i2) matchdeclare (pp, lambda ([e], polynomialp (e, [pvar]))) $
(%i3) matchdeclare (qq, lambda ([e], diff (e, pvar) # 0 and polynomialp (e, [pvar]))) $
(%i4) defmatch (match_pratio, pp/qq, pvar) $
(%i5) matchdeclare (aa, all) $
(%i6) matchdeclare (rr, lambda ([e], match_pratio (e, pvar) # false)) $
(%i7) defmatch (match_pratio_plus_remainder, rr + aa, pvar) $
(%i8) match_foo (e, pvar) := 
  block ([aa, pp, qq, rr],
    if match_pratio (e, pvar) # false
      then [0, pp, qq, pp/qq]
    elseif match_pratio_plus_remainder (e, pvar) # false
      then if polynomialp (aa, [pvar]) and op(rr) # "+"
        then [aa, pp, qq, rr]) $

以下是一些匹配的示例：

(%i9) match_foo (u^2/2 - 3*u + 1 + (u - 1)/(u^2 + u - 1), u);
            2
           u                     2            u - 1
(%o9)     [-- - 3 u + 1, u - 1, u  + u - 1, ----------]
           2                                 2
                                            u  + u - 1
(%i10) match_foo (u^2/2 - 3*u + 1 - 2*(u - 1)/(u^2 + u - 1), u);
         2
        u                           2            2 (u - 1)
(%o10) [-- - 3 u + 1, - 2 (u - 1), u  + u - 1, - ----------]
        2                                         2
                                                 u  + u - 1
(%i11) match_foo (u^2/2 - 3*u + 1 - 2/(u^2 + u - 1), u);
            2
           u                   2                2
(%o11)    [-- - 3 u + 1, - 2, u  + u - 1, - ----------]
           2                                 2
                                            u  + u - 1
(%i12) match_foo (1 - 2/(u^2 + u - 1), u);
                         2                2
(%o12)         [1, - 2, u  + u - 1, - ----------]
                                       2
                                      u  + u - 1
(%i13) match_foo (- 2/(u^2 + u - 1), u);
                         2                2
(%o13)         [0, - 2, u  + u - 1, - ----------]
                                       2
                                      u  + u - 1

以下是一些不匹配的示例：两个多项式比率项、无多项式比率和一个非多项式项。

(%i14) match_foo (1/u - 2/(u^2 + u - 1), u);
(%o14)                        false
(%i15) match_foo (1 - (u^2 + u - 1)/2, u);
(%o15)                        false
(%i16) match_foo (sin(u) - 2/(u^2 + u - 1), u);
(%o16)                        false

第二次编辑：我想我名字错match_pratio_plus_remainder了，应该是match_remainder_plus_quotient。那好吧。

推荐阅读