时间戳

首页 > 解决方案 > Neo4j-Cypher：从路径中删除一个节点并保持到路径的所有节点的链接

neo4j - Neo4j-Cypher：从路径中删除一个节点并保持到路径的所有节点的链接

问题描述

我想从路径中删除一个节点，而不危及原始路径节点。

这是我的测试数据库：

测试数据库

我想从路径中删除节点 (2)，但我希望节点 1、3、4 和 5 在路径中保持链接。

有没有办法在一个查询中做到这一点？到目前为止，我有以下内容：

MATCH p = (:Connect)-[:to*]-(:Connect)
WITH nodes(p) AS connectNodes
UNWIND connectNodes AS connectNode
WITH distinct connectNode
WHERE connectNode.connectID = 2
DETACH DELETE (connectNode)

这将删除节点 2 并取消链接路径

未链接的图表

如果没有节点2，如何保持原路径的节点之间的链接？

编辑：

我通过修改接受的答案的响应来解决它

//Make sure node (n) belongs to the path
MATCH (n:Connect {cID:2})-[:to*]-(:Connect {cID:5})
//get attached nodes, if any, ignoring directions
OPTIONAL MATCH (oa:connect)-[:to]-(n)-[:to]-(ob:connect)
//make sure nothing is duplicated 
WHERE oa.cID <> ob.cID
//Use FOREACH to mimic if/else. Only merge oa to ob if they exist. Query fails without it
FOREACH (_ IN case when oa IS NOT NULL then [true] else [] end |
    MERGE (oa)-[:to {created: 1542103211}]-(ob)
)
//Get n, and get all connected nodes to it, and delete the relationship(s)
WITH n
OPTIONAL MATCH (n)-[r:to]-(:Connect) DELETE r

标签： neo4jpathcyphergraph-databases

解决方案

这是最简单的方法是匹配将被破坏的路径，然后在删除节点的相同密码中创建新链接。

// Match the target node for deletion
MATCH (n{id:2})
// Match broken paths, if any
OPTIONAL MATCH (a)-[ra]->(n)-[rb]->(b)
// Create new link to replace destroyed ones
CREATE (a)-[r:to]->(b)
// Copy properties over, if any
SET r+=ra, r+=rb
// Remove target node
DETACH DELETE n
// If you want to keep the node and just disconnect it, replace last line with
// OPTIONAL MATCH (n)-[r:to]-() DELETE r

如果要从已删除的关系之一复制类型，可以使用APOC函数创建具有动态类型的关系。

推荐阅读