cuda - Thrust/CUDA 多次复制一个数组并结合另一个数组的值
问题描述
假设我有两个数组
A = {1, 2, 3}
和
B = {10,20,30,40,50}
我想生成一个新数组,其大小为
sizeof(A) * sizeof(B)
我想复制 B sizeof(A) 次,并且在每次重复i
时,结果数组都应该A[i]
添加到其中。所以结果会是这样的
{11,21,31,41,51,12,22,32,42,52,13,23,33,43,53}
解决方案
这个任务可以被解释为一个二维问题,其中输出数组可以被视为一个维度矩阵sizeof(A)
。sizeof(B)
这样,我们就可以使用 2D CUDA 索引来实现所需的功能。此 2D 实现的示例 CUDA C++ 代码如下所示:
#include <iostream>
#include <cuda_runtime.h>
#include <cassert>
using namespace std;
__global__ void kernel_replicate(int* a, int* b, int* c, int alen, int blen, int clen)
{
const int ai = blockIdx.x * blockDim.x + threadIdx.x;
const int bi = blockIdx.y * blockDim.y + threadIdx.y;
if(ai<alen && bi<blen)
{
const int ci = ai * blen + bi;
c[ci] = a[ai] + b[bi];
}
}
void replicate_device(int* a, int* b, int* c, int alen, int blen, int clen)
{
dim3 block(16,16);
dim3 grid;
grid.x = (alen + block.x - 1) / block.x;
grid.y = (blen + block.y - 1) / block.y;
kernel_replicate<<<grid, block>>>(a,b,c,alen,blen,clen);
assert(cudaSuccess == cudaDeviceSynchronize());
}
void replicate(int* a, int* b, int* c, int alen, int blen, int clen)
{
int *ad, *bd, *cd;
size_t abytes = alen * sizeof(int);
size_t bbytes = blen * sizeof(int);
size_t cbytes = clen * sizeof(int);
cudaMalloc(&ad, abytes);
cudaMalloc(&bd, bbytes);
cudaMalloc(&cd, cbytes);
cudaMemcpy(ad,a, abytes, cudaMemcpyHostToDevice);
cudaMemcpy(bd,b, bbytes, cudaMemcpyHostToDevice);
replicate_device(ad,bd,cd, alen,blen,clen);
cudaMemcpy(c,cd, cbytes, cudaMemcpyDeviceToHost);
cudaFree(ad);
cudaFree(bd);
cudaFree(cd);
}
int main()
{
const int alen = 3;
const int blen = 5;
const int clen = alen * blen;
int A[alen] = {1,2,3};
int B[blen] = {10,20,30,40,50};
int C[clen] = {0};
replicate(A,B,C,alen, blen, clen);
for(int i=0; i<alen; i++)
{
cout<<A[i]<<" ";
}
cout<<endl;
for(int i=0; i<blen; i++)
{
cout<<B[i]<<" ";
}
cout<<endl;
for(int i=0; i<clen; i++)
{
cout<<C[i]<<" ";
}
cout<<endl;
return 0;
}
推荐阅读
- node.js - 如何部署 MERN 应用程序,我得到“无法获取 /”
- android - 当usb在没有插头和拔出的情况下出现故障时重置usb?
- postman - 在 POSTMAN 中,我如何获取响应标题项的子字符串?
- ios - 从 Any 类型向下转换为 UIAccessibilityIdentification 总是失败
- php - 按用户名字母顺序排列多个数组
- python - 即使 18 可用,升级 pip 似乎也只安装当前版本(8.1)
- excel - Excel中的预测线性工作?
- macos - 如何使用 zlib 在 Mac OS 上构建 wxWidgets?
- java - Java 编译器正在使用旧的源代码或没有覆盖旧的类文件
- javascript - 如何使用 v-for 正确列出项目?