时间戳

首页 > 解决方案 > 如何通过 keyPressed() 更改数组的单元格？

processing - 如何通过 keyPressed() 更改数组的单元格？

问题描述

我尝试制作一个网络应用程序。您可以在此处按箭头键更改数组的单元格。有一个带有方法 display() 和 update() 的“模块”类。这些方法改变了内部数组 data[]。

class Module {
    int i; // index
    int x; // coordinate 
    int y; // coordinate 
    int[] data = new int[]{0,0,0,0,0};

    // Contructor
    Module(int x){
        this.x = x;
    }

    void update() {
        data[i]=_mas_stor;
    } 

    void display(){
        text(data[i], x, 100);
    }
}

但是如何在程序开始时设置数组的初值_mass[]呢？

整个程序在这里。

标签： processingprocessing.js

解决方案

data类中不需要数组Module。每个对象有一个数据成员就足够了。写一个构造函数，你可以传递给初始数据（Module(int x, int d)）：

class Module {
    int i;
    int x;
    int y;
    int data;
    // Contructor
    Module(int x, int d){
        this.x = x;
        this.data = d;
    }
    void update() {
        data=_mas[global_i];
    }    
    void display(){
        textSize(30);
        text(data, x, 100);
    }
}

现在可以轻松地在循环中初始化对象：

int[] _mas ={1,2,3,4,5};
int global_i = 0;
Module [] mods;

void setup() {
    size(500, 400);
    mods = new Module[5];
    for (int i = 0; i < 5; ++ i ) {
        mods[i] = new Module(i*50+50, _mas[i]);
    }
}

此外，您必须确保global_i不会超出范围keyPressed：

void keyPressed() {
    if (keyCode == UP) {
        _mas[global_i]++;
    } 
    if (keyCode == DOWN) {
        _mas[global_i]--;
    }
    if (keyCode == LEFT) {
        global_i--; 
        if (global_i < 0)
            global_i = 4;
    } 
    if (keyCode == RIGHT) {
        global_i++;
        if (global_i > 4)
            global_i = 0;
    } 
}

请注意，如果您跳过全局变量_mas并向类添加增量方法（inc）和减量方法（dec）Module而不是update方法，则可以进一步改进您的程序：

int global_i = 0;
Module [] mods;

void setup() {
    size(500, 400);
    mods = new Module[5];
    for (int i = 0; i < 5; ++ i ) {
        mods[i] = new Module(i*50+50, i);
    }
}

void draw() {
    background(50);
    for (int i = 0; i < 5; ++ i ) {
        mods[i].display();
    }
}

void keyPressed() {
    if (keyCode == UP) {
        println("up");
        mods[global_i].inc();
    } 
    if (keyCode == DOWN) {
        mods[global_i].dec();
    }
    if (keyCode == LEFT) {
        global_i--; 
        if (global_i < 0)
            global_i = 4;
    } 
    if (keyCode == RIGHT) {
        global_i++;
        if (global_i > 4)
            global_i = 0;
    } 
}

class Module {
    int i;
    int x;
    int y;
    int data;
    // Contructor
    Module(int x, int d){
        this.x = x;
        this.data = d;
    }   
    void inc() {
        this.data ++;
    }
    void dec() {
        this.data --;
    }
    void display(){
        textSize(30);
        text(data, x, 100);
    }
}

推荐阅读