时间戳

首页 > 解决方案 > 停止 Prolog 推断值

prolog - 停止 Prolog 推断值

问题描述

如果我运行solved([[x, o, o], [o, o, o], [o, o, o]])它应该输出 true 因为只有x，如果我运行solved([[x, o, o], [o, o, o], [o, o, x]])它应该输出 false 因为有超过 1 x。但是，运行它会一直输出 true，因为它会推断 C 的值。

:- use_module(library(clpfd)).

rotate_clock(Xss, Zss) :-
   transpose(Xss, Yss),
   maplist(reverse, Yss, Zss).

rotate_anti(Xss, Zss) :-
   maplist(reverse, Xss, Yss),
   transpose(Yss, Zss).

linjmp([x, x, o | T], [o, o, x | T]).
linjmp([o, x, x | T], [x, o, o | T]).
linjmp([H|T1], [H|T2]) :- linjmp(T1,T2).

horizjmp([A|T],[B|T]) :- linjmp(A,B).
horizjmp([H|T1],[H|T2]) :- horizjmp(T1,T2).

jump(B,A) :- horizjmp(B,A).
jump(B,A) :- rotate_clock(B,BR), horizjmp(BR,BRJ), rotate_anti(BRJ, A).

num_x(A, C) :- count(A, x, C).

count([],X,0).
count([X|T],X,Y):- count(T,X,Z), Y is 1+Z.
count([_|T],X,Z):- count(T,X,Z).

sum_list([], 0).
sum_list([H|T], Sum) :-
   sum_list(T, Rest),
   Sum is H + Rest.

solved(A) :-
   maplist(num_x, A, B),
   sum_list(B, C),
   C == 1.

标签： prologclpfd

解决方案

与其试图改变一种语言的行为（这可能是可能的，但当然是一个挑战），不如调查一下为什么 Prolog 最终会找到一个Cwith C == 1。如果我们自己评估maplist(num_x, A, B), 我们会看到：

?- maplist(num_x, [[x, o, o], [o, o, o], [o, o, x]], B).
B = [1, 0, 1] ;
B = [1, 0, 0] ;
B = [0, 0, 1] ;
B = [0, 0, 0].

所以看起来num_x/2谓词可以为同一个列表生成多个结果：对于一个列表x，它首先生成1，然后生成0。

如果我们使用以下方法进行一些测试，则可以确认这一点count/3：

?- count([x, o, o], x, C).
C = 1 ;
C = 0.

?- count([x, x, o], x, C).
C = 2 ;
C = 1 ;
C = 1 ;
C = 0.

因此，似乎count/3每次都有一个回溯点，可以决定是否计算给定的x。

事实上，如果我们看一下count/3谓词，我们会看到：

count([],X,0).
count([X|T],X,Y):- count(T,X,Z), Y is 1+Z.
count([_|T],X,Z):- count(T,X,Z).

所以这里对于一个非空列表，有两种方式子句：一个是头部等于X，我们要计算的元素，在这种情况下Y is 1+Z，但是最后一个子句说，不管头部的值是什么， Prolog 不会计算该元素。Prolog 执行回溯，因此最终会选择这两个子句。

我们可以添加一个dif/2来添加头部和X应该不同的约束，例如：

count([],X,0).
count([X|T],X,Y):- count(T,X,Z), Y is 1+Z.
count([H|T],X,Z):- dif(H, X), count(T,X,Z).

所以现在如果一个X出现在列表中，我们将计算那个元素。

推荐阅读