时间戳

首页 > 解决方案 > 如何检测 Tcl 协程的完成？

tcl - 如何检测 Tcl 协程的完成？

问题描述

我想在 Tcl 中找到一种检测协程结束的好方法。考虑：

coroutine cor apply {{} {
    yield 1
    yield 2
    yield 3
}}

try {
    puts [cor]
    puts [cor]
    puts [cor]
    puts [cor]
} trap {TCL LOOKUP COMMAND cor} {e} {
    puts "done"
}

这行得通，但感觉就像一个黑客，而且很脆弱。如果我重命名cor并忘记在陷阱中重命名它，它将失败。如果我cor在陷阱中省略了，它将捕获不相关的拼写错误。

一定有更好的方法。它是什么？

标签： tclcoroutine

解决方案

要检测命令是否仍然存在，请使用info commands并检查它返回的列表的长度。（我假设您可以保证命令名称中没有 glob 字符；如果这是真的，那么检查非常便宜。）

while {[llength [info commands cor]]} {
    puts [cor]
}

但是，如果您打算将协程用作生成器并且仅在循环中使用，则可以让它直接发出信号表明它已完成。为此，让它产生一个break.

coroutine cor apply {{} {
    yield [info coroutine];  # A sensible result from [coroutine]
    yield 1
    yield 2
    yield 3
    return -code break
    # [tailcall break] would also work
}}

while true {
    puts [cor]
}

诀窍是你不要 yield休息；您将其用作协程的最终结果。（您的旧协程正在使用yieldas that 的结果，可能主要是靠运气。）

在写这篇文章时，我注意到了一个错误。运行协程的循环在 8.6.8（我检查过的唯一版本）的顶层不起作用。不知道为什么。在过程/apply上下文中很好（将协程名称作为参数传递是很自然的）：

apply {c {
    while true {
        puts [$c]
    }
}} cor

这些不同运行方式的字节码看起来并没有明显的不同。强制解释也会使事情正常进行，这很好地表明这是一个真正的错误。

set while while
$while true {
    puts [cor]
}

推荐阅读