batch-file - 来自单个 ECHO 命令的连接文本文件输出将字符插入到预期输出后第二次打印的字符串中

Question

我正在尝试创建一个批处理文件以在 225 个批处理文件中的字符串内的特定位置插入来自.txt文件的字符串 - 即，插入到文件中特定位置的一行 - 但这个问题涉及插入部分，而不是循环部分，所以我在我的代码示例中省略了后者。它目前也只是在屏幕上显示文本；实际上并未将其写入文件。

目标文件是一组用于使用工具运行游戏服务器集群的启动.bat文件，因此我必须将它们中的每一个都保留为与它们开头相同的名称（Start XXYY.bat）。它们包含以下内容：

start /high ShooterGame\Binaries\Win64\ShooterGameServer.exe Ocean?ServerX=0?ServerY=0?AltSaveDirectoryName=0000?ServerAdminPassword=1234?MaxPlayers=50?ReservedPlayerSlots=25?QueryPort=50002?Port=5002?SeamlessIP=192.168.1.225?RCONEnabled=true?RCONPort=28450 -log -server -NoBattlEye
exit

其中ServerX、ServerY、AltSaveDirectoryNamen和所有三个Port设置对于每个服务器都是唯一的，因此必须保持不变。

我需要从最终版本中的另一个.txt文件中添加更多设置，但对于这个示例，我只会将添加内容（在ReservedPlayerSlots设置之后添加的单词INSERT，同时保持每个设置用问号分隔）直接放入此脚本。

我的代码实际上正在做我想做的事，但不幸的是它并没有停止，而是决定附加比我想要的更多的文本；具体来说，我添加到ECHO命令中的所有内容都不是变量名。

为了澄清，我得到了我想要的确切输出......加上不需要添加的一堆问号和单词INSERT，这显然来自我的ECHO命令，但我只是不知道为什么它们会被重新添加。

我对批处理脚本的了解相当有限，因此很可能有一些我忽略了的基本知识。

我尝试用普通字母替换输出中的问号（在最终版本中必须是问号），但它不会改变行为；它们仍然附加到预期的输出中，就像它们替换的问号一样。

@ECHO OFF

SET FileNum=0000
REM I will have the code loop through 225 files (0000-1414) in the final version, but for test purposes I just set it to one single file number manually here.

SET FileName=Start %FileNum%.bat
REN "%FileName%" temp.txt
FOR /F "tokens=1,2,3,4,5,6,7,8,9,10,11,12 delims=?" %%a IN (temp.txt) DO (
   ECHO %%a?%%b?%%c?%%d?%%e?%%f?%%g?INSERT?%%h?%%i?%%j?%%k?%%l
)
REN temp.txt "%FileName%"

我希望这段代码输出这个：

start /high ShooterGame\Binaries\Win64\ShooterGameServer.exe Ocean?ServerX=0?ServerY=0?AltSaveDirectoryName=0000?ServerAdminPassword=1234?MaxPlayers=50?ReservedPlayerSlots=25?INSERT?QueryPort=50002?Port=5002?SeamlessIP=192.168.1.225?RCONEnabled=true?RCONPort=28450 -log -server -NoBattlEye
exit

但我得到的是：

start /high ShooterGame\Binaries\Win64\ShooterGameServer.exe Ocean?ServerX=0?ServerY=0?AltSaveDirectoryName=0000?ServerAdminPassword=1234?MaxPlayers=50?ReservedPlayerSlots=25?INSERT?QueryPort=50002?Port=5002?SeamlessIP=192.168.1.225?RCONEnabled=true?RCONPort=28450 -log -server -NoBattlEye
exit???????INSERT?????

哪个是预期的输出，但是在ECHO命令中意外重新添加了每个符号，这些符号在输出末尾没有指定变量（在这种情况下???????INSERT?????） ，就在出口之后。

我很难过......我希望有人知道我在这里做错了什么。

标签： batch-filecmd

Answer 1

好的，我应用了 aschipfl 提供的想法，现在它似乎可以工作了。

在我使用另一个ECHO添加带有出口的最后一行之后，该IF NOT "%%b"==""行似乎已经成功了。我的完整脚本（包括循环和写入文件）现在是这样的：

@ECHO OFF
SETLOCAL EnableDelayedExpansion
SET "Insert=SettingOne=True?SettingTwo=False?SettingThree=1.000000"
FOR /l %%x IN (0, 1, 14) DO (
    FOR /l %%y IN (0, 1, 14) DO (
        IF %%x LSS 10 (SET XNum=0%%x) ELSE (SET XNum=%%x)
        IF %%y LSS 10 (SET YNum=0%%y) ELSE (SET Ynum=%%y)
        SET "FileNum=!XNum!!YNum!"
        SET "FileName=Start !FileNum!.bat"
        ECHO Filename: !FileName!
        REN "!FileName!" temp.txt
        (
            FOR /F "tokens=1-12 delims=?" %%a IN (temp.txt) DO (
                IF NOT "%%b"=="" (
                    ECHO %%a?%%b?%%c?%%d?%%e?%%f?%%g?%Insert%?%%h?%%i?%%j?%%k?%%l
                    ECHO exit
                )
            )
        ) >edited.txt
        REN edited.txt "!FileName!"
        DEL /q temp.txt
        ECHO has been updated
    )
)

这现在完全按预期工作。

很有可能有一种更优雅的方式来做到这一点，我很确定有一种方法可以使这种方式更通用，更少硬编码，但这对于我的目的来说已经足够了。

我感谢你的帮助！