时间戳

首页 > 解决方案 > 如何设置 CMake 以使用 clang 为 Windows 上嵌入的 ARM 进行交叉编译？

c++ - 如何设置 CMake 以使用 clang 为 Windows 上嵌入的 ARM 进行交叉编译？

问题描述

我正在尝试生成 Ninja makefile 以使用 Clang 为 ARM Cortex A5 CPU 交叉编译 C++ 项目。我为 CMake 创建了一个工具链文件，但似乎有一个错误或我找不到的东西丢失。当使用下面的工具链文件调用 CMake 时，出现以下错误。

CMake 命令：

cmake -DCMAKE_TOOLCHAIN_FILE="..\Src\Build\Toolchain-clang-arm.cmake" -GNinja ..\Src\

输出：

-- C 编译器标识为 Clang 7.0.0 CMake Error at C:/Users/user/scoop/apps/cmake/3.13.4/share/cmake-3.13/Modules/CMakeDetermineCompilerId.cmake:802 (message): The Clang编译工具

“C:/程序文件/LLVM/bin/clang.exe”

以 MSVC ABI 为目标，但具有类似 GNU 的命令行界面。这是不支持的。请改用“clang-cl”，例如通过在环境中设置“CC=clang-cl”。此外，使用 MSVC 命令行环境。调用堆栈（最近的调用优先）：
C:/Users/user/scoop/apps/cmake/3.13.4/share/cmake-3.13/Modules/CMakeDetermineCCompiler.cmake:113 (CMAKE_DIAGNOSE_UNSUPPORTED_CLANG) CMakeLists.txt:2 (PROJECT)

-- 配置不完整，出现错误！

CMake 工具链文件（Toolchain-clang-arm.cmake）：

set(CMAKE_CROSSCOMPILING TRUE)
SET(CMAKE_SYSTEM_NAME Generic)
set(CMAKE_SYSTEM_PROCESSOR arm)

# Clang target triple
SET(TARGET armv7-none-eabi)

# specify the cross compiler
SET(CMAKE_C_COMPILER_TARGET ${TARGET})
SET(CMAKE_C_COMPILER clang)
SET(CMAKE_CXX_COMPILER_TARGET ${TARGET})
SET(CMAKE_CXX_COMPILER clang++)
SET(CMAKE_ASM_COMPILER_TARGET ${TARGET})
SET(CMAKE_ASM_COMPILER clang)

# C/C++ toolchain
SET(TOOLCHAIN "C:/Program Files (x86)/GNU Tools ARM Embedded/7 2018-q2-update")
SET(CMAKE_C_COMPILER_EXTERNAL_TOOLCHAIN ${TOOLCHAIN})
SET(CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN ${TOOLCHAIN})

# specify compiler flags
SET(ARCH_FLAGS "-target armv7-none-eabi -mcpu=cortex-a5")
SET(CMAKE_C_FLAGS "-Wall -Wextra ${ARCH_FLAGS}" CACHE STRING "Common flags for C compiler")
SET(CMAKE_CXX_FLAGS "-Wall -Wextra -std=c++11 -fno-exceptions -fno-threadsafe-statics ${ARCH_FLAGS}" CACHE STRING "Common flags for C++ compiler")

我使用CMake和Clang文档以及来自网络的一些随机链接来创建工具链文件。整个项目使用 ARM GCC for Windows 编译得很好，所以工具链文件似乎是唯一缺失的部分。

编辑

我试图通过强制编译器来解决 CMake 编译器检查。我用 SET(CMAKE_C_COMPILER clang)、SET(CMAKE_CXX_COMPILER clang++) 等替换这些行：

CMAKE_FORCE_C_COMPILER(clang Clang)
CMAKE_FORCE_CXX_COMPILER(clang++ Clang)

错误保持不变。

编辑

我可以使用 clang -target arm-none-eabi 成功编译一个 hello world 示例。所以问题似乎出在 CMake 中。我在 CMake 问题跟踪器中创建了一个错误。

工具版本：

标签： c++windowscmakearmclang

解决方案

我的问题已通过对我的错误报告的回复得到解答，但我在此处添加了答案，以便将所有信息集中在一个地方以供将来参考。

简而言之：如果您从llvm.org安装 Clang，CMake 目前不支持使用 clang/clang++ 命令行界面。如果您想使用 clang/clang++ 接口（对于 ARM 进行交叉编译是必需的），您必须通过msys2安装 Clang 。

详细地

Windows 上的 Clang 有两种不同的命令行界面：

  • clang/clang++尝试与 GCC gcc/g++ 兼容并针对 GNU ABI 的默认接口
  • clang-cl尝试与 Microsoft 的 Visual C++ 编译器 cl.exe 兼容并针对 MSVC ABI

为了对 ARM 进行交叉编译，您需要 clang/clang++ 接口。问题是 CMake 支持不同的接口，具体取决于您安装 Clang 的方式（有关更多详细信息，请参阅 CMake 问题跟踪器中的错误）：

  • 如果您从llvm.org安装 Clang，则CMake 仅支持 clang-cl 接口。
  • 如果您通过msys2安装 Clang， CMake 支持 clang/clang++ 接口。

所以这就是我所做的：

  1. 安装msys2
  2. 使用pacman安装 Clang 和 CMake 。msys2中有两个clang包，一个mingw32和一个mingw64版本。我使用了 mingw64 包（mingw-w64-x86_64-clang）。
  3. 启动 mingw64 shell 并运行 CMake 并从那里构建。

工具链文件

我的原始工具链文件有两个问题需要我很长时间才能解决。所以我希望这可以节省其他人一些时间：

  1. 目标三元组（例如 arm-none-eabi）需要与 GCC binutils 的前缀完全匹配。我的 binutils 的前缀是 arm-none-eabi（例如 arm-none-eabi-ar），所以我必须相应地更改目标三元组。
  2. CMAKE_TRY_COMPILE_TARGET_TYPE需要更改为 STATIC_LIBRARY 以防止 CMake 在编译检查期间运行链接器。

这是我使用的最终工具链文件（你也可以在这个GitHub存储库中找到一个很好的工具链文件示例）：

cmake_minimum_required(VERSION 3.13)

set(CMAKE_SYSTEM_NAME Generic)
set(CMAKE_SYSTEM_PROCESSOR ARM)

if(DEFINED ENV{GCC_ARM_TOOLCHAIN})
    set(GCC_ARM_TOOLCHAIN $ENV{GCC_ARM_TOOLCHAIN})
else()
    set(GCC_ARM_TOOLCHAIN "C:/Users/user/tools/gcc-arm-none-eabi-7-2018-q2-update-win32")
endif()

LIST(APPEND CMAKE_PROGRAM_PATH ${GCC_ARM_TOOLCHAIN})

# Specify the cross compiler
# The target triple needs to match the prefix of the binutils exactly
# (e.g. CMake looks for arm-none-eabi-ar)
set(CLANG_TARGET_TRIPLE arm-none-eabi)
set(GCC_ARM_TOOLCHAIN_PREFIX ${CLANG_CLANG_TARGET_TRIPLE})
set(CMAKE_C_COMPILER clang)
set(CMAKE_C_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})
set(CMAKE_CXX_COMPILER clang++)
set(CMAKE_CXX_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})
set(CMAKE_ASM_COMPILER clang)
set(CMAKE_ASM_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})

# Don't run the linker on compiler check
set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)

# Specify compiler flags
set(ARCH_FLAGS "-mcpu=cortex-a5 -mthumb -mfpu=neon-vfpv4 -mfloat-abi=hard -mno-unaligned-access")
set(CMAKE_C_FLAGS "-Wall ${ARCH_FLAGS}" CACHE STRING "Common flags for C compiler")
set(CMAKE_CXX_FLAGS "-Wall -std=c++17 -fno-exceptions -fno-rtti -fno-threadsafe-statics ${ARCH_FLAGS}" CACHE STRING "Common flags for C++ compiler")
set(CMAKE_ASM_FLAGS "-Wall ${ARCH_FLAGS} -x assembler-with-cpp" CACHE STRING "Common flags for assembler")
set(CMAKE_EXE_LINKER_FLAGS "-nostartfiles -Wl,-Map,kernel.map,--gc-sections -fuse-linker-plugin -Wl,--use-blx --specs=nano.specs --specs=nosys.specs" CACHE STRING "")

# C/C++ toolchain
set(GCC_ARM_SYSROOT "${GCC_ARM_TOOLCHAIN}/${GCC_ARM_TOOLCHAIN_PREFIX}")
# set(CMAKE_SYSROOT ${GCC_ARM_SYSROOT})
set(CMAKE_FIND_ROOT_PATH ${GCC_ARM_SYSROOT})

# Search for programs in the build host directories
set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
# For libraries and headers in the target directories
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)

推荐阅读