batch-file - 如果我选择变量 2，批处理文件会一直关闭

Question

我目前正在批量制作自己的 ADB 工具包菜单，所以我继续测试了批处理文件，但如果我选择变量 2，它总是退出批处理文件。我该怎么办？

@echo off
:MENU
cls
title ADB TOOLKIT
echo.
echo.
echo                                              ----------------------------
echo                                              ADB TOOLKIT MADE BY TECHDARK
echo                                              ----------------------------
echo.                            
echo.
echo ----------------------------------------------------
echo 1) Install APK
echo 2) Unlock phone
echo 3) Lock phone
echo ----------------------------------------------------
set /p select=type 1,2 or 3
if %select%==1 goto install
if %select%==2 goto unlock
if %select%==3 goto lock

:install
cls
echo What do you want to install?
set /p Input=Type in apk:
cls
echo installing...
echo.
adb install "apps\%Input%"
pause
goto menu

:lock
cls
adb shell input keyevent 26
cls
echo Your phone is locked!
pause
goto menu

:unlock
cls
echo Do your phone have a password or PIN
set /p pswd==(y/n)
if %pswd%==y goto pswdunlock
if %pswd%==n goto nopswdunlock
pause

:nopswdunlock
cls
adb shell input keyevent 26
cls
echo Your phone is locked!
pause
goto menu

:pswdunlock
cls
echo What is your PIN/Password?
set /p PIN=Type PIN/Pswd here:
cls
echo unlocking
echo.
adb shell input keyevent 26 && adb shell input keyevent 1 && adb shell input text %PIN% && adb shell input keyevent 66
pause
goto menu

标签： batch-fileadb

Answer 1

我建议为该任务使用以下较短的代码：

@echo off

:menu
cls

title ADB TOOLKIT
echo.
echo.
echo   ----------------------------
echo   ADB TOOLKIT MADE BY TECHDARK
echo   ----------------------------
echo.
echo.
echo ---------------
echo 1) Install APK
echo 2) Unlock phone
echo 3) Lock phone
echo ---------------

choice /c:123 /M "Type 1, 2 or 3: " /N
cls

if errorlevel 3 goto lock
if errorlevel 2 goto unlock
if errorlevel 1 goto install

:install
echo What do you want to install?
set /p "install=Type in apk: "
cls
echo Installing...
echo.
adb install "apps\%install%"
pause
goto menu

:lock
adb shell input keyevent 26
cls
echo Your phone is locked!
pause
goto menu

:unlock
choice /C:yn /M "Does your phone have a password or PIN? "

if errorlevel 2 goto nopswdunlock
if errorlevel 1 goto pswdunlock

pause

:nopswdunlock
cls
adb shell input keyevent 26
cls
echo Your phone is locked!
pause
goto menu

:pswdunlock
cls
set /p "PIN=What is your PIN/Password? Type here: "
cls
echo Unlocking, please wait...
echo.
adb shell input keyevent 26 && adb shell input keyevent 1 && adb shell input text %PIN% && adb shell input keyevent 66
pause
goto menu

请参阅choice /?和set /?了解有关此处使用的命令的作用的信息。