model - Promela 同时随机选择两个元素

当您只需要从连续的数字区间中提取一对值时idx，您可以通过以下方式轻松解决保证问题：idy[LOW, UPP]N = UPP - LOW + 1idx != idy

挑选idx_[LOW, UPP]
挑选idy_[LOW, UPP - 1]

调整idywrt 的值。的值idx如下：

idy = LOW + (((idx - LOW) + 1 + (idy - LOW)) % N)

也就是说，您将其解释idy为固定位移。idx. 请注意，这种方法不会影响概率分布，特别是从概率的角度来看idy，它不会idy依赖于。idx

例子：

#define BLACK_BALLS 4
#define WHITE_BALLS 10
#define TOTAL_BALLS 14

bool box[TOTAL_BALLS];

inline my_select(var, upper) {
    if
        ::  0 <= upper -> var =  0;
        ::  1 <= upper -> var =  1;
        ::  2 <= upper -> var =  2;
        ::  3 <= upper -> var =  3;
        ::  4 <= upper -> var =  4;
        ::  5 <= upper -> var =  5;
        ::  6 <= upper -> var =  6;
        ::  7 <= upper -> var =  7;
        ::  8 <= upper -> var =  8;
        ::  9 <= upper -> var =  9;
        :: 10 <= upper -> var = 10;
        :: 11 <= upper -> var = 11;
        :: 12 <= upper -> var = 12;
        :: 13 <= upper -> var = 13;
    fi;
}

proctype pick_two_balls() {
    byte idx;
    byte idy;

    my_select(idx, TOTAL_BALLS - 1);
    my_select(idy, TOTAL_BALLS - 2);

    printf("Initial picks:\n")

    printf("\tpicked %d in [0, %d]\n", idx, TOTAL_BALLS - 1);
    printf("\tpicked %d in [0, %d]\n", idy, TOTAL_BALLS - 2);

    idy = ((idx + 1) + idy) % (TOTAL_BALLS);

    printf("Adjusted picks:\n");

    printf("\tball #01 at index %d\n", idx);
    printf("\tball #02 at index %d\n", idy);

    printf("Final Balls:\n");

    if
        :: box[idx]  -> printf("\tbox[%d] = black\n", idx);
        :: !box[idx] -> printf("\tbox[%d] = white\n", idx);
    fi;

    if
        :: box[idy]  -> printf("\tbox[%d] = black\n", idy);
        :: !box[idy] -> printf("\tbox[%d] = white\n", idy);
    fi;
}

init {
    byte idx = 0;
    byte todo = BLACK_BALLS;

    do  // not guaranteed to terminate!
        :: todo > 0 ->
            my_select(idx, TOTAL_BALLS - 1) ->
            if
                :: box[idx] ->
                    skip;
                :: else ->
                    box[idx] = true;
                    todo = todo - 1;
            fi;
        :: else ->
            break;
    od;

    for (idx: 0 .. TOTAL_BALLS - 1) {
        if
            :: box[idx] ->
                printf("box[%d] = black\n", idx);
            :: !box[idx] ->
                printf("box[%d] = white\n", idx);
        fi;
    }
    run pick_two_balls();
}

输出：

~$ spin p.pml 
      box[0] = white
      box[1] = black
      box[2] = white
      box[3] = white
      box[4] = white
      box[5] = white
      box[6] = white
      box[7] = white
      box[8] = white
      box[9] = white
      box[10] = white
      box[11] = black
      box[12] = black
      box[13] = black
          Initial picks:
            picked 9 in [0, 13]
            picked 7 in [0, 12]
          Adjusted picks:
            ball #01 at index 9
            ball #02 at index 3
          Final Balls:
            box[9] = white
            box[3] = white
2 processes created

注意＃1：在正常情况下，我会使用该select语句而不是编写自己的my_select(var, upper)函数。但是，select不能保证分配给的值var是通过均匀分布选取的，我认为这对您来说可能是个问题。

注意#2：当您需要提取多个索引时，上面的数学表达式没有帮助。但是，您可以在机械意义上应用相同的原则：维护used_indexes为 bool 的支持数组，其中位置k是true如果它被某个索引使用。每次选择一个新的 indexi时，都会从数组的开头开始计算空单元格，然后减i一。一旦i = 0你有了应该在原始数组中使用的“真实索引” ，你就将该位置标记为在.jused_indexes

model - Promela 同时随机选择两个元素

问题描述

解决方案

推荐阅读