haskell - 使用类型类约束快速检查并报告生成的值？

Question

我正在尝试为国际象棋游戏进行基于属性的测试。我已经设置了以下类型类

class Monad m => HasCheck m where                                                   
    isCollision :: Coord -> m Bool                                                  

它检查给定坐标是否包含碰撞或超出范围。

现在我有一个函数可以为骑士生成允许动作的移动集，如下所示

collisionKnightRule :: HasCheck m => Coord -> m (Set Coord)                      
collisionKnightRule =                                                            
    Set.filterM isCollision . knightMoveSet                                      


-- | Set of all moves, legal or not                                              
knightMoveSet :: Coord -> Set Coord                                              
knightMoveSet (x,y) =                                                            
    Set.fromList                                                                 
        [ (x+2,y-1),(x+2,y+1),(x-2,y-1),(x-2,y+1)                                
        , (x+1,y-2),(x+1,y+2),(x-1,y-2),(x-1,y+2)                                
        ]                                                                        



knightMoves :: HasCheck m => Coord -> m (Set Coord)                              
knightMoves pos =                                                                
    do  let moveSet =                                                            
                knightMoveSet pos                                                
        invalidMoves <- collisionKnightRule pos                                        
        return $ Set.difference moveSet invalidMoves                             

以及任意坐标的 HasCheck 类的实例

instance HasCheck Gen where                                                      
    isCollision _ =                                                              
         Quickcheck.arbitrary                                                    

因此，为了测试这一点，我想确保生成的移动集是所有可能移动的正确子集。

knightSetProperty :: Piece.HasCheck Gen                                          
    => (Int,Int)                                                                 
    -> Gen Bool                                                                  
knightSetProperty position =                                                     
    do  moves <- Piece.knightMoves position                                      
        return $ moves `Set.isProperSubsetOf` (Piece.knightMoveSet position)

-- ... later on

it "Knight ruleset is subset" $                                          
            quickCheck knightSetProperty

当然这失败了，因为它可能是骑士不能移动到任何地方，这意味着它不是一个适当的子集，而是同一个集合。但是报告的错误并不是特别有用

*** Failed! Falsifiable (after 14 tests and 3 shrinks):  
(0,0)

这是因为 quickcheck 不报告 isCollision 的生成值。因此我想知道，我怎样才能让 quickCheck 报告生成的值isCollision？

标签： haskelltestingtypeclassquickcheck

Answer 1

好的，所以我觉得这应该可以用另一种方式解决。但是，我提出了以下受处理程序模式启发的解决方案。

我将 HasCheck 类型类更改为一条记录，如下：

data Handle = MakeHandle                                                                   
    { isCollision   :: Coord -> Bool                                                   
    }      

然后重构所有代码以使用句柄而不是 HasCheck。

collisionKnightRule :: Handle -> Coord -> (Set Coord)                            
collisionKnightRule handle =                                                     
    Set.filter (isCollision handle) . knightMoveSet                              


-- | Set of all moves, legal or not                                              
knightMoveSet :: Coord -> Set Coord                                              
knightMoveSet (x,y) =                                                            
    Set.fromList                                                                 
        [ (x+2,y-1),(x+2,y+1),(x-2,y-1),(x-2,y+1)                                
        , (x+1,y-2),(x+1,y+2),(x-1,y-2),(x-1,y+2)                                
        ]                                                                        


-- | Set of illegal moves                                                        
knightRuleSet :: Handle -> Coord -> (Set Coord)                                  
knightRuleSet =                                                                  
    collisionKnightRule                                                          


knightMoves :: Handle -> Coord -> (Set Coord)                                    
knightMoves handle pos =                                                         
    let                                                                          
        moveSet =                                                                
            knightMoveSet pos                                                    

        invalidMoves =                                                           
            knightRuleSet handle pos                                             
    in                                                                           
        Set.difference moveSet invalidMoves

这样做的缺点是我担心对于有状态的代码很容易引入一个错误，如果你传入一个过时的句柄，IE 有多个事实来源。一个优点是这对于 Haskell 新手来说可能更容易理解。我们现在可以使用 Quickcheck 的 Function 类型类来模拟函数，并将它们作为参数传递给一个 mockHandler：

knightSetProperty ::                                                                 
    Fun (Int,Int) Bool                                                               
    -> (Int,Int)                                                                     
    -> Gen Bool                                                                      
knightSetProperty (Fun _ isCollision) position =                
    let                                                                              
        handler = 
            Piece.MakeHandle isCollision                           
        moveSet =                                                                      
            Piece.knightMoves handler position                                       
    in                                                                               
        return $ moveSet `Set.isProperSubsetOf` (Piece.knightMoveSet position)

现在通过一个反例正确地失败了：

*** Failed! Falsifiable (after 53 tests and 74 shrinks):     
{_->False}
(0,0)