时间戳

首页 > 解决方案 > 如何在 NetLogo 中识别一群乌龟？

netlogo - 如何在 NetLogo 中识别一群乌龟？

问题描述

有没有人有任何解决方案让乌龟识别一群其他乌龟，即一群乌龟聚集在一起？以下方法不起作用，因为半径内的 50 只海龟可能是不同的（到处都是，而不是彼此靠近）：

if count turtles in-radius 20 >= 50 [show "There's a crowd"]

目前，我将人群定义为 50 多只海龟并排站立。

标签： netlogo

解决方案

如果您想要连续连接的海龟，您可以修改模型库中的 Patch Clusters Example - 这是一个版本。使用此设置：

globals [ groups>50 ]

turtles-own [ 
  my-group
]

to setup
  ca
  crt 500 [
    set my-group -99
    set shape "square"
    move-to one-of patches
  ]  
  reset-ticks
end

这些辅助函数：

to identify-groups
  let group-counter 0

  loop [
    let seed one-of turtles with [ my-group = -99 ]

    if seed = nobody [
      stop
    ]
    ask seed [
      set my-group group-counter
      set group-counter group-counter + 1
      spread-group
    ]
  ]
end  

to spread-group
  set label my-group
  set color my-group * 10 + 5 
  ask ( turtles-on neighbors ) with [ my-group = -99 ] [
    set my-group [my-group] of myself
    spread-group
  ]
end

identify-groups运行一个循环来识别连续斑块上的所有海龟，并my-group在这些组之间传播一个唯一值。

然后，您可以获取唯一的组值并用于filter仅返回有一些阈值海龟计数的组号：

to go 
  identify-groups

  let unique-groups sort remove-duplicates [my-group] of turtles

  set groups>50 filter [ i -> count turtles with [ my-group = i ] >= 50  ] unique-groups

  print groups>50
end

推荐阅读