时间戳

首页 > 解决方案 > Perl6：按值排序哈希并使用 kv

sorting - Perl6：按值排序哈希并使用 kv

问题描述

我正在查看以下数据（JSON 格式）

{
  "FValidation_pipelineMTHXT_v4.5.1_refLibV2": "concordance2/f",
  "FValidation_pipelineLPJL": "concordance2/c",
  "FCompetenceRuns": "concordance2/b",
  "FWGS": "concordance2/a",
  "Falidation_pipelineMTHXT": "concordance2/e",
  "FValidation_pipelineLPJL_v4.5.1_refLibV2": "concordance2/d"
}

我正在尝试按哈希值排序

for %files.kv -> $key, $value {

提供所需的数据，但我希望它排序。我尝试了大约 20 种不同的方法，但都不起作用

for %files.sort.kv  -> ($key, $value) {

和

for %files.sort: *.value.kv  -> ($key, $value) {

灵感来自https://docs.perl6.org/routine/sort#(Map)_method_sort 等等，但没有一个有效:(

如何按值对该哈希进行排序？

标签： sortinghashmapcomparatorrakucolumnsorting

解决方案

.kv返回一个平面序列。

my %h = (
  a => 3,
  b => 2,
  c => 1,
);

say %h.kv.perl;
# ("a", 3, "c", 1, "b", 2).Seq

如果您对它进行排序，那么您这样做时不会保留键及其关联值。

say %h.kv.sort.perl;
# (1, 2, 3, "a", "b", "c").Seq

因此，您想在拆分对之前对其进行排序。

# default sort order (key first, value second)
say %h.sort.perl;
# (:a(3), :b(2), :c(1)).Seq

say %h.sort: *.value;       # sort by value only (tied values are in random order)
# (:c(1), :b(2), :a(3)).Seq
say %h.sort: *.invert;      # sort by value first, key second
# (:c(1), :b(2), :a(3)).Seq
say %h.sort: *.kv.reverse;  # sort by value first, key second
# (:c(1), :b(2), :a(3)).Seq

排序后，您可以将其视为一系列 Pair 对象：

# default $_
for %h.sort: *.invert {
  say .key ~ ' => ' ~ .value
}

# extract as named attributes
for %h.sort: *.invert -> (:$key, :$value) {
  say "$key => $value"
}

# more explicit form of above
for %h.sort: *.invert -> Pair $ (:key($key), :value($value)) {
  say "$key => $value"
}

或者您可以在排序后将它们分开：（
注意两级结构。）

say %h.sort(*.invert).map(*.kv).perl;
# (("c", 1).Seq, ("b", 2).Seq, ("a", 3).Seq).Seq
say %h.sort(*.invert)».kv.perl;
# (("c", 1).Seq, ("b", 2).Seq, ("a", 3).Seq).Seq

# default $_
for %h.sort(*.invert).map(*.kv) {
  say .key ~ ' => ' ~ .value
}

# extract inner positional parameters
for %h.sort(*.invert).map(*.kv) -> ($k,$v) {
  say "$k => $v"
}

# `».kv` instead of `.map(*.kv)`
for %h.sort(*.invert)».kv -> ($k,$v) {
  say "$k => $v"
}

您甚至可以在拉开成对对象后将其展平。

say %h.sort(*.invert).map(*.kv).flat.perl;
# ("c", 1, "b", 2, "a", 3).Seq
say %h.sort(*.invert)».kv.flat.perl;
# ("c", 1, "b", 2, "a", 3).Seq

for %h.sort(*.invert).map(*.kv).flat -> $k, $v {
  say "$k => $v"
}

for %h.sort(*.invert)».kv.flat -> $k, $v {
  say "$k => $v"
}

（请注意，».method只映射一个方法调用。要映射两个你需要».method1».method2，或者只使用 map .map(*.method1.method2)。
所以在».kv.flat上面，只有.kv方法被映射到值。）

推荐阅读