时间戳

首页 > 解决方案 > 从外部 XML 文件中定义的输入文件中删除元素或属性

xml - 从外部 XML 文件中定义的输入文件中删除元素或属性

问题描述

我想维护一个外部 XML 文件，我将在其中保留应该从输入文件中删除的那些元素/属性。因此，每当需要删除新元素/属性时，我都会将其添加到我的外部 XML 文件中。

我创建了一个 XSLT，它通过将传入文件中的名称与我的外部文件匹配来删除一个元素。问题是，这不匹配所有元素，只有第一次出现被删除。我要删除的元素/属性可以出现在输入文件中的任何位置。

我的 XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" encoding="ISO-8859-1" indent="yes"/>
    <xsl:template match="/">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*">
        <xsl:copy>
            <!-- @=attribuutti -->
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="node()[name() = name(document('TagsDB.xml')/INVOICE_CENTER/ElementsToRemove/*)]"/>
</xsl:stylesheet>

输入.XML

<INVOICE_CENTER>
    <CONTENT_FRAME>
        <Test1>123</Test1>
        <INVOICES>
            <INVOICE>
                <HEADER>
                    <PROCESS_CODE>00</PROCESS_CODE>
                </HEADER>
                <ROWS>
                    <ROW>
                        <ROW_NUMBER>0</ROW_NUMBER>
                        <Test2>12345</Test2>
                    </ROW>
                </ROWS>
            </INVOICE>
        </INVOICES>
    </CONTENT_FRAME>
</INVOICE_CENTER>

我的外部文件 (TagsDB.xml) 我提到了应该删除的元素/属性：

<INVOICE_CENTER>
    <ElementsToRemove>
        <Test1/>
        <Test2/>
    </ElementsToRemove>
    <AttributesToRemove Att1="" Att2=""/>
</INVOICE_CENTER>

预期结果是：

<INVOICE_CENTER>
    <CONTENT_FRAME>
        <INVOICES>
            <INVOICE>
                <HEADER>
                    <PROCESS_CODE>00</PROCESS_CODE>
                </HEADER>
                <ROWS>
                    <ROW>
                        <ROW_NUMBER>0</ROW_NUMBER>
                        </ROW>
                </ROWS>
            </INVOICE>
        </INVOICES>
    </CONTENT_FRAME>
</INVOICE_CENTER>

因此，应该从 XML 中删除 Test1 和 Test2，因为它们是在我的外部 XML 文件中定义的。

标签： xmlxpathxslt-1.0

解决方案

该name()函数返回所选节点集中第一个节点的名称。您需要将您的条件表述为：

如果外部文档不包含名称等于该元素名称的元素

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="*">
    <xsl:if test="not(document('TagsDB.xml')/INVOICE_CENTER/ElementsToRemove/*[name()=name(current())])">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

要处理属性，您可以执行以下操作：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="*">
    <xsl:if test="not(document('TagsDB.xml')/INVOICE_CENTER/ElementsToRemove/*[name()=name(current())])">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:if>
</xsl:template>

<xsl:template match="@*">
    <xsl:if test="not(document('TagsDB.xml')/INVOICE_CENTER/AttributesToRemove/@*[name()=name(current())])">
        <xsl:copy/>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

推荐阅读