时间戳

首页 > 解决方案 > 在 Terraform 0.12 中连接两个列表 - concat()

terraform - 在 Terraform 0.12 中连接两个列表 - concat()

问题描述

我想在 Terraform 0.12 中连接两个数组。在我的示例中，有公共子网和私有子网。我想将它们都分配给相同的网络访问列表。以下代码缩短：

data "aws_subnet_ids" "private" {
    vpc_id = aws_vpc.main.id
    tags = {
        subnet-type  = "private"
    }
}

data "aws_subnet_ids" "public" {
    vpc_id = aws_vpc.main.id
    tags = {
        subnet-type  = "public"
    }
}


resource "aws_network_acl" "networks" {
    vpc_id = aws_vpc.main.id

    subnet_ids = concat(data.aws_subnet_ids.private.ids, data.aws_subnet_ids.public.ids)
    [...]
}

如果我使用以下输出：

output "private_subnets" {
  value = data.aws_subnet_ids.private.ids
}

output "public_subnets" {
  value = data.aws_subnet_ids.public.ids
}

生成以下输出：

private_subnets = [
  "subnet-243zr427rhhfjseb9",
  "subnet-we789rh2438fchb6e",
  "subnet-092rz7g82fhhkui74",
]
public_subnets = [
  "subnet-12230qegvg764e9d",
  "subnet-123465svgvgf0d7e",
]

所以一切都应该工作。但是会出现以下错误：

iptizer@machine:~/src/infra$ terraform12 apply
[...]

Error: Invalid function argument

  on nacls.tf line 19, in resource "aws_network_acl" "networks":
  19:     subnet_ids = concat(data.aws_subnet_ids.private.ids, data.aws_subnet_ids.public.ids)
    |----------------
    | data.aws_subnet_ids.private.ids is set of string with 3 elements

Invalid value for "seqs" parameter: all arguments must be lists or tuples; got
set of string.

错误..或者我错过了什么？

标签： terraform

解决方案

与 0.11 相比，Terraform 0.12 对列表值和集合值进行了更强的区分，并且包括一些类似这样的额外检查。

在这种特殊情况下，concat以这种方式失败，因为连接要求所有元素具有明确定义的顺序，以便结果也可以具有明确定义的顺序。集合没有排序，所以这个检查是为了提醒您在转换为列表时明确选择合适的排序，或者根本不转换为列表。

在这种特殊情况下，排序似乎并不特别重要，因此实现的词汇排序sort可能就足够了：

  subnet_ids = concat(
    sort(data.aws_subnet_ids.private.ids),
    sort(data.aws_subnet_ids.public.ids),
  )

（因为从字符串列表集到字符串列表的转换也强加了词法顺序，这在功能上等同tolist于字符串集。我通常更喜欢sort这里，因为它为未来的读者提供了一个线索，即结果将按词法顺序排列。）

另一种选择是在集合世界中说，并setunion改用：

  subnet_ids = setunion(
    data.aws_subnet_ids.private.ids,
    data.aws_subnet_ids.public.ids,
  )

由于这两个列表之间不应该有重复，因此您在此处使用哪种方法并不重要，但为了完整起见，我会注意到，如果这两个集合包含相同的子网 id，则setunion操作将对它们进行重复数据删除，因为每个唯一值在一组中只能出现零次或一次。

在我写这篇文章的时候，count仍然是在集合中为每个项目创建一个资源实例的主要方法，通常需要最终转换为列表，以便各个实例可以具有所需的顺序。一旦for_each实现，在这样的情况下使用集合而不是列表将有一个优势：

resource "aws_instance" "per_subnet_example" {
  # resource-level for_each is not implemented at the time of writing,
  # but planned for a future release.
  for_each = setunion(
    data.aws_subnet_ids.private.ids,
    data.aws_subnet_ids.public.ids,
  )

  # ...
}

当使用for_each集合而不是 时count，Terraform 将通过集合中的值而不是连续索引来识别每个实例，因此该资源中的一个实例可能具有 address aws_instance.per_subnet_example["subnet-abc123"]，这意味着当从该集合中添加和删除元素时 Terraform可以只创建/销毁相应的单个实例，而不是在有序序列更改后可能重新创建所有内容。

Terraform 提供者在有意义的地方使用这样的集合，以便使这种for_each模式在它到达后更易于使用，但不幸的是，这意味着我们需要同时编写一些额外的显式类型转换，以便明确我们以类似序列的方式而不是类似集合的方式重新处理这些值。

推荐阅读