时间戳

首页 > 解决方案 > 在 perl 中立即调用函数表达式 (IIFE) 的最佳方法？

perl - 在 perl 中立即调用函数表达式 (IIFE) 的最佳方法？

问题描述

借用 Javascript 中的术语，perl 中 IIFE 的“最佳实践”方式是什么？

我下面的测试代码是一个简单的循环调用匿名 sub 并立即执行它以构建一个 subs 数组（它只返回循环索引）。这主要是我想要的，但是我需要使用一个中间变量（而不是使用@_，它会在内部函数上发生变化）。

use warnings;
use strict;
my @funcs;
for(my $i=0;$i<3;$i++) {
    sub  {
        my $index=shift;
        $funcs[$index]=sub {$index};
    }
    -> ($i);
}

for (@funcs) {
    print &$_()."\n";
}

#Output
0
1
2

我知道我可以用它map来重组这个问题。但抛开这些不谈，有没有更好的方法来做到这一点？

更新

感谢@ikegami 强调了一些要点。

只是为了将来对这个问题的看法，我对此的看法：

'iterator' for 循环与'c 风格' for 循环具有不同的作用域（它是地图吗？）。这完全不需要 IIFE 就可以清理代码。甜的。

更新 2

以下代码显示了我看到的差异。不是说一个比另一个更好，但很高兴知道我认为。我之后的输出是 0 1 2 但第一个只重复 $i 的最后一个值（在 ++ 运算符之后为 3）。

use warnings;
use strict;
my @funcs;
print "C loop direct assignment of sub\n";
for(my $i=0;$i<3;$i++) {
    $funcs[$i]= sub {$i};
}
print &$_()."\n" for @funcs;

print "C loop direct assignment of sub with variable\n";
for(my $i=0;$i<3;$i++) {
    my $index=$i; #assignment/copy
    $funcs[$index]= sub {$index};
}
print &$_()."\n" for @funcs;

print "For loop interator\n";
@funcs=[];
for my $i (0..2) {
    $funcs[$i]=sub {$i};
}
print &$_()."\n" for @funcs;

print "C loop with IIFE assignment\n";
@funcs=[];
for (my $i=0;$i<3;$i++) {
    sub  {
    my $index=shift;
        $funcs[$index]=sub {$index};
    }
    -> ($i);
}
print &$_()."\n" for @funcs;

输出是：

C loop direct assignment of sub                                                                                                                                          
3                                                                                                                                                                        
3                                                                                                                                                                        
3         
C loop direct assignment of sub with variable                                                                                                                            
0                                                                                                                                                                        
1                                                                                                                                                                        
2                                                                                                                                                                            
For loop interator                                                                                                                                                       
0                                                                                                                                                                        
1                                                                                                                                                                        
2                                                                                                                                                                        
C loop with IIFE assignment                                                                                                                                                           
0                                                                                                                                                                        
1                                                                                                                                                                        
2

标签： perlanonymous-function

解决方案

Perl 等价于

(function () {
   var x = ...;
   ...
})();

是

sub {
   my $x = ...;
   ...
}->();

也就是说，IIFE 只是 Perl 中根本不需要的一种解决方法。

(function () {
   var x = ...;
   ...
})();

是一种解决方法

{
   my $x = ...;
   ...
}

和

var result = (function () {
   return ...;
})();

是一种解决方法

my $result = do {
   ...
};

看起来您正在尝试翻译类似于以下内容的内容：

let funcs = [];
for (let i=0; i<3; ++i) {
   (function() {
      var index = i;
      funcs.push( function() { return index; } );
   })();
}

for (let func of funcs)
   console.log(func());

以下为直接翻译：

my @funcs;
for (my $i=0; $i<3; ++$i) {
   sub {
      my $index = $i;
      push @funcs, sub { $index };
   }->();
}

say $_->() for @funcs;

但是使用 IIFE 根本没有意义。只需使用以下内容：

my @funcs;
for (my $i=0; $i<3; ++$i) {
   my $index = $i;
   push @funcs, sub { $index };
}

say $_->() for @funcs;

现在，人们倾向于避免在 Perl 中使用 C 风格的 for 循环，因为使用 foreach 循环更具可读性（而且效率更高！）。它还使解决方案更加简单，因为 foreach 循环的循环变量的范围是循环体，而不是循环语句。

my @funcs;
for my $i (0..2) {
   push @funcs, sub { $i };
}

say $_->() for @funcs;

推荐阅读