qmake - QMake 和 pkg-config

Question

我在我的一个 Qt 应用程序中使用 libqtermwidget。碰巧在库的 0.8.0 版本中，引入了一些 0.6.0 版本中没有的新功能。

由于 libqtermwidget 不提供任何版本宏，我想在 qmake 中使用 pkg-config 检查其版本，如下所示：

# i would like a functionality like this
if pkg-config --version qtermwidget5 < 0.8.0
    DEFINES += OLD_QTERMWIDGET

这当然可以在 cpp 文件中使用：

#ifndef OLD_QTERMWIDGET
    ... code for 0.8.0 and higher ...
#endif

标签： qmakepkg-config

Answer 1

您应该使用$$system()来调用pkg-config和读取标准输出（如果有）。但是让我们以更“通用”的方式对其进行编程：

# finds package version by invoking 'pkg-config'
# $$1 = package
# note: stores value in cache (stash) file for subsequent use
defineReplace(findPackage) {
    # using <package>Version variable
    pkg = $${1}Version
    !defined($$pkg, var) {
        # cache miss
        # note: $$pkgConfigExecutable() is an undocumented function from qt_functions.prf
        $$pkg = $$system($$pkgConfigExecutable() --modversion $$1)
        # cannot store the empty value
        isEmpty($$pkg): $$pkg = 0
        # save to the stash file
        cache($$pkg, stash)
    }
    # return value of <package>Version
    return($$eval($$pkg))
}


# now using this...
qtw5 = $$findPackage(qtermwidget5)
equals(qtw5, 0) {
    error("qtermwidget5 is not installed")
} else:!versionAtLeast(qtw5, 0.8.0) {
    warning("Found an old version of qtermwidget5 ($$qtw5)")
    DEFINES += OLD_QTERMWIDGET
} else {
    # nothing
}