时间戳

首页 > 解决方案 > Fortran 函数一次性获取指针的关联状态和大小

class - Fortran 函数一次性获取指针的关联状态和大小

问题描述

我正在编写一个 Fortran (2003) 整数函数来检查指向任意元素数组的指针的关联状态和大小，使用class(*). 如果没有关联，则返回 -1，否则返回数组元素的数量。假设指针被定义为指向null()。

目标是避免两个后续if语句。（我知道在 C 中可以将 2 个检查组合成一个语句。）

该代码在 gfortran (6.1.0) 和 Intel ifort (17.0.4) 下编译和运行，但只有 gfortran 提供了所需的结果。

包含测试例程和名为“size_field”的函数的完整代码如下所示：

program tpa  
implicit none  
real,pointer :: tp(:)=>null()  

                      write (6,*) size_field(tp)  
allocate   (tp(53));  write (6,*) size_field(tp)  
deallocate (tp);      write (6,*) size_field(tp)  
tp=>null();           write (6,*) size_field(tp)  
allocate   (tp(0));   write (6,*) size_field(tp)  
deallocate (tp);      write (6,*) size_field(tp)  

contains

   function size_field(ff)  
   integer :: size_field  
   class(*),target  :: ff(:)  
   class(*),pointer :: field(:)  
   field => ff  
   size_field=-1 ! shall indicate not associated  
   if (associated(field)) size_field=size(field)  
   end function  

end program

使用 gfortran（默认编译器选项）编译，输出符合预期： 

-1
53
-1
-1
 0  
-1

使用 ifort（默认编译器选项）编译，输出为： 

 0  
53  
53  
53  
 0  
 0

为什么 ifort 没有给出我想要的结果？
如果我替换class(*)为real，则 ifort 编译的程序也会显示正确的结果。

标签： classfortranpolymorphismintel-fortran

解决方案

您的程序不是有效的 Fortran。当被要求编译这个程序时，允许编译器给出它喜欢的任何结果。

哑论ff

   class(*), target :: ff(:)

是一个非指针、非可选的虚拟参数，因此（Fortran 2018 15.5.2.3 p1）引用函数时的任何指针实际参数size_field，在这种情况下tp，必须是与目标关联的指针。

在第一个引用tp上，没有指针关联。

至于如何满足您的要求，“非可选”部分是一个很大的提示。在 Fortran 2008+ 下，可以将虚拟参数设为可选，然后在引用函数时实际参数不需要与指针关联。如果实际参数与指针无关，则虚拟参数不存在：

function size_field(ff)
  integer :: size_field
  class(*), target, optional :: ff(:)

  if (PRESENT(ff)) then
    size_field = SIZE(ff)
  else
    size_field = -1
  end if

end function

但是，在问题的情况下，解决限制的“非可选”部分是唯一有用的方法。试图将虚拟参数改为指针是没有帮助的：对于多态虚拟指针参数，实际参数也必须是多态的（并且对于无限多态虚拟，实际参数也必须是无限多态的）。

推荐阅读