excel - EXCEL列出一个范围内的所有数字？

Question

Excel 版本 1907

给定第一列，我想要一个生成第二列的函数

004-005 | (004|005)
006-007 | (006|007)
009     | (009)
010-046 | (010|011|012|013|014|015...045|046)

目前手动执行此操作，但它只是不可扩展

标签： excel

Answer 1

如果您有 Office 365 Excel，您可以使用 TEXTJOIN 作为数组公式：

="("&TEXTJOIN("|",TRUE,TEXT(ROW(INDEX($ZZ:$ZZ,--LEFT(A1,3)):INDEX($ZZ:$ZZ,--RIGHT(A1,3))),"000"))&")"

作为一个数组公式，退出编辑模式时必须使用 Ctrl-Shift-Enter 而不是 Enter 来确认。

---

如果没有 Office 365，此 udf 会模仿该功能。

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function

将其放入模块中并使用上述公式。