时间戳

首页 > 解决方案 > 将 FOR 与动态内部表一起使用？

for-loop - 将 FOR 与动态内部表一起使用？

问题描述

我想将下面的方法转换为嵌套的 FOR 而不是嵌套的 LOOP，但我不知道该怎么做，因为内部表是动态的（它可以是 5 种不同类型之一）。

TYPES: BEGIN OF ty_result,
         lgart TYPE string,
         betrg TYPE string,
         betpe TYPE string,
       END OF ty_result,
       ty_results TYPE STANDARD TABLE OF ty_result WITH EMPTY KEY.
DATA: known_table       TYPE ty_results,
      also_known_table  TYPE ty_results,
      mt_period_results TYPE ty_results.

FIELD-SYMBOLS: <dynamic_table> TYPE STANDARD TABLE,
               <betrg>, <betpe>, <lgart>.

LOOP AT known_table REFERENCE INTO DATA(known_line).

  READ TABLE <dynamic_table> TRANSPORTING NO FIELDS WITH KEY ('LGART') = known_line->*-lgart.

  IF sy-subrc <> 0. CONTINUE. ENDIF.

  DATA(lv_tabix) = sy-tabix.

  LOOP AT <dynamic_table> ASSIGNING FIELD-SYMBOL(<dynamic_line>) FROM lv_tabix.

    UNASSIGN: <betrg>, <betpe>, <lgart>.

    ASSIGN COMPONENT: 'BETPE' OF STRUCTURE <dynamic_line> TO <betpe>,
                      'BETRG' OF STRUCTURE <dynamic_line> TO <betrg>,
                      'LGART' OF STRUCTURE <dynamic_line> TO <lgart>.


    IF <lgart> <> known_line->*-lgart.
      EXIT.
    ENDIF.

    APPEND VALUE ty_result( lgart = <lgart>
                            betrg = <betrg>
                            betpe = <betpe> ) TO mt_period_results.

  ENDLOOP.
ENDLOOP.

当内表不是动态的时，我可以这样做：

 append lines of value zwta_t_results(
   for known_line in known_table
    for also_known_line  in also_known_table 
      where ( lgart = known_line-lgart )
        ( lgart = known_line-lgart
          betrg = also_known_line-betrg
          betpe = also_known_line-betpe ) to mt_period_results.

所以问题是：是否可以将 FOR 迭代器（作为第二种方法）与动态表一起使用？

标签： for-loopdynamicabap

解决方案

我的答案是针对 ABAP 7.52 检查的。不幸的是，目前只能ASSIGN通过LET <fs> = writable_expression IN在构造表达式（包括“ FOR”表迭代）中使用静态变体的子集，其中“可写表达式”仅限于表表达式、NEW 和 CAST。所以它相当有限，没有动态变体的等价物ASSIGN，因此您只能使用变通方法。

后面的语法WHERE允许动态表达式，因此可以输入WHERE ('LGART = KNOWN_LINE-LGART'). 但是，如果循环嵌套在另一个循环中（就像您的情况一样），它可能会非常适得其反，因此应该定义一个索引以加速迭代。如果要使用二级索引，则条件应为USING KEY ('KEYNAME') WHERE ('LGART = KNOWN_LINE-LGART')。

现在，这是针对您的特定情况的解决方法：您静态定义组件的名称，因此一种可能性是使用这些组件名称定义静态结构并使用CORRESPONDING构造运算符。请注意，我没有对其进行测试，但我认为 using 的性能CORRESPONDING在您的情况下比 using 更快有几个原因ASSIGN。

以下代码应该可以工作。我假设后面的内部表有一个按( )<dynamic_table>排序的主键，这样性能就不错了：LGARTTYPE SORTED TABLE OF ... WITH NON-UNIQUE KEY lgart

TYPES: BEGIN OF ty_struc,
         lgart TYPE string,
         betrg TYPE string,
         betpe TYPE string,
       END OF ty_struc.

known_table = VALUE #( ( lgart = 'A' ) ( lgart = 'B' ) ).
also_known_table = VALUE #( ( lgart = 'A' ) ( lgart = 'C' ) ( lgart = 'A' ) ).
ASSIGN also_known_table TO <dynamic_table>.

APPEND LINES OF
    VALUE ty_results(
      FOR known_line IN known_table
        FOR <inner_line> IN <dynamic_table>
          WHERE ('LGART = KNOWN_LINE-LGART')
          LET struc = CORRESPONDING ty_struc( <inner_line> ) IN
          ( lgart = known_line-lgart
            betrg = struc-betrg
            betpe = struc-betpe ) )
    TO mt_period_results.

推荐阅读