batch-file - 内部变量的延迟扩展
问题描述
我正在尝试在 for 中扩展一些变量。我不知道如何解释这一点,但我认为代码很好地显示了我想要做的事情。
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET arr[0]=C:\Users\me\Desktop\abc
SET arr[1]=C:\Users\me\Desktop\abc2
SET /A arrLastElement=1
CALL :subroutine %arrLastElement% arr
EXIT /B 0
:subroutine
SET lineToExecute=FORFILES /m "*.*" /c "cmd /c echo !dir!"
FOR /L %%i in (0, 1, %1) DO (
SET dir=!%2[%%i]!
ECHO !dir!
ECHO !lineToExecute!
)
EXIT /B 0
实际结果:
C:\Users\me\Desktop\abc
FORFILES /m "*.*" /c "cmd /c echo "
C:\Users\me\Desktop\abc2
FORFILES /m "*.*" /c "cmd /c echo "
预期结果:
C:\Users\me\Desktop\abc
FORFILES /m "*.*" /c "cmd /c echo C:\Users\me\Desktop\abc"
C:\Users\me\Desktop\abc2
FORFILES /m "*.*" /c "cmd /c echo C:\Users\me\Desktop\abc2"
我应该如何编写这段代码?
解决方案
您正在寻找嵌套延迟扩展。有几种方法可以实现它。我认为最简单的是这个:
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET arr[0]=C:\Users\me\Desktop\abc
SET arr[1]=C:\Users\me\Desktop\abc2
SET /A arrLastElement=1
CALL :subroutine %arrLastElement% arr
EXIT /B 0
:subroutine
SET lineToExecute=FORFILES /m "*.*" /c "cmd /c echo %%dir%%"
FOR /L %%i in (0, 1, %1) DO (
SET dir=!%2[%%i]!
ECHO !dir!
call ECHO !lineToExecute!
)
EXIT /B 0
推荐阅读
- macros - 从 Enter 确认 Atom 解除绑定更正
- python - 为什么 Python XLSWRITER 单元格公式不能以编程方式工作?
- linux-kernel - 将 writecombine 区域映射到用户空间文档
- javascript - 输入框通过单击按钮来提醒文本(对 JQuery 来说真的很新)
- sql-server - 在 SQL Server 中解析 XML(使用数组)
- bash - 在 WSL Ubuntu 上克隆时,Bash github 项目无法运行
- ruby - 如何在wix api网站上的ruby on rails应用程序上的api调用帖子中获取身份验证代码?
- javascript - 科尔多瓦作物插件
- angular - Angular Cesium - 使用 ac-model 更改颜色
- java - 具有 keycloak 实例的角色权限