时间戳

首页 > 解决方案 > TServerSocket：如何在发送消息之前检查 ListView 上的特定客户端是否仍然连接？

sockets - TServerSocket：如何在发送消息之前检查 ListView 上的特定客户端是否仍然连接？

问题描述

例如，我有一个Timer并希望向每个客户端发送一条消息以ListView确定 ping 时间。然后我有以下代码：

procedure TMainForm.Timer1Timer(Sender: TObject);
var
  i: Integer;
begin
  try
    for i := 0 to ListView1.Items.count - 1 do
    begin
      ListView1.Items.Item[i].SubItems.Objects[2] := TObject(GetTickCount);
      ServerSocket1.Socket.Connections[i].SendText('ping' + #13#10);
    end;
  except
    exit;
  end;
end;

在发送之前，可能更适合检查客户端是否真的连接或类似的。这个怎么做？提前致谢。

标签： socketsdelphidelphi-10.3-rio

解决方案

无需检查连接。如果客户端实际上已断开连接，则当您的处理程序被触发时，它将不再位于服务器的Connections[]列表中。OnTimer您应该有一个OnClientDisconnect分配给 的处理程序以TServerSocket从TListView.

如果由于某种原因，客户端仍在Connections[]列表中（即，因为底层连接已丢失但TServerSocket尚未检测到它），则套接字将简单地缓存所有传出数据，直到其出站缓冲区填满，然后它将开始WSAWOULDBLOCK为每次发送返回错误。最终，操作系统将超时死连接并将TServerSocket其从Connections[]列表中删除，从而触发OnClientDisconnect事件。

至少，在您显示的代码中，您应该将您的发送循环更新为Close()任何实际发送失败的套接字，从而触发OnClientDisconnect事件以从 中删除该客户端TListView，例如：

procedure TMainForm.ServerSocket1ClientConnect(Sender: TObject; Socket: TCustomWinSocket);
var
  Item: TListItem;
begin
  Item := ListView1.Items.Add;
  Item.Data := Socket;
  ...
end;

procedure TMainForm.ServerSocket1ClientDisconnect(Sender: TObject; Socket: TCustomWinSocket);
var
  Item: TListItem;
begin
  Item := ListView1.FindData(0, Socket, True, False);
  if Item <> nil then
    Item.Delete;
end;

procedure TMainForm.Timer1Timer(Sender: TObject);
const
  s: AnsiString = 'ping' + #13#10;
var
  Item: TListItem;
  Socket: TCustomWinSocket;
  p: PAnsiChar;
  i, len, sent: Integer;
begin
  for i := 0 to ListView1.Items.Count - 1 do
  begin
    Item := ListView1.Items[i];
    Item.SubItems.Objects[2] := TObject(GetTickCount);
    Socket := TCustomWinSocket(Item.Data);
    try
      // SendText() does not handle partial sends, or Unicode strings...
      //Socket.SendText('ping' + #13#10);
      p := PAnsiChar(s);
      len := Length(s);
      repeat
        sent := Socket.SendBuf(p^, len);
        if sent = -1 then
        being
          if WSAGetLastError() <> WSAEWOULDBLOCK then
            Break;
          // TODO: stop trying after several attempts fail...
          Continue;
        end;
        Inc(p, sent);
        Dec(len, sent);
      until len = 0;
      if len = 0 then
        Continue;
    except
    end;
    Socket.Close;
  end;
end;

推荐阅读