excel - 在即时窗口中显示变量数组值

Question

我正在使用第三方加载项，这似乎可以正常工作。但是，我无法在即时窗口中显示变量数组元素的值。我找到了解决方法，但我仍然想知道问题是什么以及如何解决它。

有一个包含数据的对象变量。

Dim odsDataSeries As DataSeries
Set odsDataSeries = odfData.GetSeries("ELY(high)")

在监视窗口中，您可以看到名为“索引”的变量数组...

在即时窗口中，我键入...

?odsDataSeries.Index(1)

但它给出错误消息“参数数量错误或属性分配无效”

如果我使用加入，那么我会得到数据......

?join(odsDataSeries.Index)
3/01/2020 2/01/2020 31/12/2019 etc... 

在我的代码中，我还能够编写...

Dim v As Variant
v = odsDataSeries.Index
Stop

然后，当我在即时窗口中查询 v 中的元素时，它可以工作......

?v(1)
2/01/2020 

所以我的问题是......为什么我的即时窗口查询“？odsDataSeries.Index（1）”不起作用？有一段时间我认为 Index 不是公共的，我无法编写循环来处理数组（除非我将数组放入另一个变量中，否则我仍然不能，如上所示）。请注意，在我的代码中编写此代码会给出相同的错误消息（在编译时）。

我正在添加我的整个子以供参考。请注意，我使用了早期绑定。excel 插件是一个.xll 文件，我看不到里面的代码（因为我还没有 COM 技能）。

Dim av As New AlphaVantageExcelDataCOMFunctions

Public Sub PublicLoadData()
On Error GoTo 0
Dim odfData As DataFrame
    Set odfData = av.AVGetEquityTimeSeries("ELY", "Daily", True, "compact")
Dim odsDataSeries As DataSeries
    Set odsDataSeries = odfData.GetSeries("ELY(high)")
Dim v As Variant
    v = odsDataSeries.Index
    Debug.Print GetVariableType(odsDataSeries.Index)
    Stop
End Sub 'PublicLoadData

我的 GetVariableType() 函数返回“变体数组”。如果您想要此代码，请告诉我。

所以问题再次是......在我输入的即时窗口中......

?odsDataSeries.Index(1)

但它给出错误消息“参数数量错误或属性分配无效”

如果我使用加入，那么我会得到数据......

?join(odsDataSeries.Index)
3/01/2020 2/01/2020 31/12/2019 etc... 

当我在即时窗口中查询 v 中的元素时，它可以工作......

?v(1)
2/01/2020 

这是 DataSeries 文档的链接

标签： excelvbavariant-array

Answer 1

假设有一个对象someObject的方法（或属性）getArray没有输入参数并返回一个数组。

您可以通过与不显式传递参数arr = someObject.getArray相同的方式来检索数组。arr = someObject.getArray()要通过一行代码从该数组中检索单个元素，您应该这样做someObject.getArray()(0)，其中第一个括号指的是方法调用，第二个括号表示该元素在数组中的索引。

请注意，虽然该表达式someObject.getArray()(i)适用于单个元素请求，例如在立即窗口中，但如果在循环中使用，则可能会导致每次迭代检索数组的开销很大。因此，您应该在循环之前将数组放入变量中。

这是显示常用Dictionary对象的一些棘手行为的示例。您可以通过dict.Keys(i)早期绑定从方法返回的键数组中检索元素：

Sub testEarlyBoundDict()

    ' Need to include a reference to "Microsoft Scripting Runtime"

    Dim earlyBoundDict As Dictionary
    Set earlyBoundDict = New Dictionary
    Set earlyBoundDict = CreateObject("Scripting.Dictionary")
    earlyBoundDict("myKey") = "myValue"
    Debug.Print earlyBoundDict.Keys(0)

End Sub

但是如果你使用后期绑定，那么你必须编写额外的括号：

Sub testLateBoundDict()

    ' Need no references

    Dim lateBoundDict As Object
    Set lateBoundDict = CreateObject("Scripting.Dictionary")
    lateBoundDict("myKey") = "myValue"
    Debug.Print lateBoundDict.Keys()(0)
    Debug.Print lateBoundDict.Keys(0) ' fails

End Sub

要创建防故障代码，我建议始终使用someObject.getArray()(i).