时间戳

首页 > 解决方案 > 如何在 Haskell 中使用 Monad 类的多个构造函数参数上映射函数？

haskell - 如何在 Haskell 中使用 Monad 类的多个构造函数参数上映射函数？

问题描述

我偶然发现的问题与>>=应用到这样的样本类型有关：

data ThreeArgs a = ThreeArgs a a a deriving (Show,Eq)

instance Functor ThreeArgs where
    fmap f (ThreeArgs a b c) = ThreeArgs (f a) (f b) (f c)

instance Applicative ThreeArgs where
    pure x = ThreeArgs x x x
    (ThreeArgs a b c) <*> (ThreeArgs p s q) = ThreeArgs (a p) (b s) (c q)

我将声明一个 Monad 实例如下：

instance Monad ThreeArgs where
    return x = ThreeArgs x x x
    (ThreeArgs a b c) >>= f = f ... -- a code I need to complete

是的，它看起来好像f适用于所有三个ThreeArgs构造函数参数。如果我完成最后一行

(ThreeArgs a b c) >>= f = f a

那么编译器没有任何抱怨，而结果是：

*module1> let x = do { x <- ThreeArgs 1 2 3; y <- ThreeArgs 4 6 7; return $ x + y }
*module1> x
ThreeArgs 5 5 5

这意味着求和会导致具有相同参数值的上下文，尽管正确的输出应该是ThreeArgs 5 8 10. 一旦我编辑为

(ThreeArgs a b c) >>= f = (f a) (f b) (f c)

编译器警报：

 Couldn't match expected type `ThreeArgs b
                                -> ThreeArgs b -> ThreeArgs b -> ThreeArgs b'
              with actual type `ThreeArgs b'

所以，我看到一个严重的错误引导了我的理解，但我仍然很难理解 Haskell 中的单子类和其他类似的东西。大概，我想在这里使用递归还是其他什么？

标签： haskellfunctional-programmingmonads

解决方案

ThreeArgs同构于((->) Ordering)。见证：

to :: ThreeArgs a -> Ordering -> a
to (ThreeArgs x _ _) LT = x
to (ThreeArgs _ y _) EQ = y
to (ThreeArgs _ _ z) GT = z

from :: (Ordering -> a) -> ThreeArgs a
from f = ThreeArgs (f LT) (f EQ) (f GT)

您的Functor和Applicative实例与它们的((->) r)工作方式相匹配，因此我们只需使其与它的Monad工作方式相匹配，我们就完成了。

instance Monad ThreeArgs where
    ThreeArgs x y z >>= f = ThreeArgs x' y' z' where
        ThreeArgs x' _ _ = f x
        ThreeArgs _ y' _ = f y
        ThreeArgs _ _ z' = f z

顺便说一句，ThreeArgs如果您想了解更多相关信息，则数据结构之类的通用术语是“可表示函子”。

推荐阅读