时间戳

首页 > 解决方案 > 在 VB6 中从 ComboBox 保存数据的问题

sql - 在 VB6 中从 ComboBox 保存数据的问题

问题描述

我有，ComboBox但问题是当我尝试保存选择的值时，因为我加载了ComboBox值SQLServer并且应用程序向我显示了下一个错误：

[Microsoft][ODBC SQL Server Driver][SQL Server]列名“cellular”无效。

我加载的ComboBox值为SQL：

Private Sub Form_Load()
   Set rs = New Recordset
   rs.CursorLocation = adUseServer

   Call IniciarConexion

   CargaIDTipoNumero
End Sub

Private Sub CargaIDTipoNumero()
    cmbAddExample(indice).Clear
    rs.Open "SELECT tipo FROM tipo_Numero", cnn, adOpenDynamic, adLockOptimistic
    Do While rs.EOF = False
        cmbAddExample(indice).AddItem rs!tipo
        rs.MoveNext
    Loop
    rs.Close
End Sub

Private Sub IniciarConexion()
    Set cnn = New ADODB.Connection
    With cnn
        .CursorLocation = adUseClient
        .Open "PROVIDER=MSDASQL;driver={SQL Server};server=server;uid=uid;pwd=pwd;database=database;"
    End With
End Sub

保存以下值的表ComboBox：

CREATE TABLE ejTres(
    combo int
)

我加载的表ComboBox：

CREATE TABLE tipo_Numero(
    idTipo INT IDENTITY (1,1) NOT NULL, 
    tipo VARCHAR (10) NOT NULL, 
    CONSTRAINT pk_tipo PRIMARY KEY(idTipo)
)

INSERT INTO tipo_Numero(tipo)
VALUES('celular'), ('fijo')

以及Button我保存值的位置：

Private Sub btnGuardar_Click()
Dim i As Integer
Dim CM As ADODB.Command

Set CM = New ADODB.Command
Set CM.ActiveConnection = cnn
    CM.CommandType = adCmdText
    CM.CommandText = "INSERT INTO ejTres (combo) VALUES (?)"
    CM.Parameters.Append CM.CreateParameter("@combo", adInteger, , , cmbAddExample(i))
    CM.Execute , , adExecuteNoRecords
End Sub

标签： sqlsql-servercomboboxvb6

解决方案

只关注如何将 Identity 值放入表中的问题，请尝试以下操作：

''as you load the combo, also save the identity value

Do While rs.EOF = False
   cmbAddExample(indice).AddItem rs!tipo
   cmbAddExample(indice).ItemData(cmbAddExample(indice).NewIndex) = rs!idTipo
   rs.MoveNext
Loop


''now retrieve the identity value when creating the parameter

id = cmbAddExample(i).ItemData(cmbAddExample(i).ListIndex)

Set CM = New ADODB.Command
Set CM.ActiveConnection = cnn
CM.CommandType = adCmdText
CM.CommandText = "INSERT INTO ejTres (combo) VALUES (?)"
CM.Parameters.Append CM.CreateParameter("@combo", adInteger, , , id)
CM.Execute , , adExecuteNoRecords

推荐阅读