时间戳

首页 > 解决方案 > Terraform：使用 azurerm 的子网

azure - Terraform：使用 azurerm 的子网

问题描述

错误信息

执行时收到以下错误消息terraform apply：

错误：创建/更新虚拟网络“CTI-NETWORK”（资源组“CTI-RESOURCES”）时出错：network.VirtualNetworksClient#CreateOrUpdate：发送请求失败：StatusCode=400 -- 原始错误：Code="InUseSubnetCannotBeDeleted" Message="Subnet /subscriptions/d92e8f07-e127-4015-b67a-a547af76fdfc/resourceGroups/CTI-RESOURCES/providers/Microsoft.Network/networkInterfaces/CTI-NIC-PRD1/ipConfigurations/CTI-IP-PRD1 正在使用 CTI-PRD删除。要删除子网，请删除子网内的所有资源。请参阅 aka.ms/deletesubnet。详细信息=[]

我假设我有一个依赖混合但似乎无法弄清楚。

代码片段

main.tf 的内容

provider "azurerm" {
    version         = "=1.38.0"
    subscription_id = "d92e8f07-e127-4015-b67a-a547af76fdfc"
}

resource "azurerm_resource_group" "resourcegroup" {
    name            = "${var.prefix}RESOURCES"
    location        = var.location
}

resource "azurerm_virtual_network" "network" {
    name                = "${var.prefix}NETWORK"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    address_space       = ["10.0.0.0/16"]
    location            = var.location
}

resource "azurerm_subnet" "prd-subnet" {
    name                 = "${var.prefix}PRD"
    resource_group_name  = azurerm_resource_group.resourcegroup.name
    virtual_network_name = azurerm_virtual_network.network.name
    address_prefix       = "10.0.0.0/24"
}

resource "azurerm_subnet" "tst-subnet" {
    name                 = "${var.prefix}TST"
    resource_group_name  = azurerm_resource_group.resourcegroup.name
    virtual_network_name = azurerm_virtual_network.network.name
    address_prefix       = "10.0.1.0/24"
}

resource "azurerm_public_ip" "ip-prd-1" {
    name                = "${var.prefix}PIP-PRD1"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location
    allocation_method   = "Dynamic"
    domain_name_label   = "vm-prd-1"
}


resource "azurerm_network_interface" "nic-prd-1" {
    name                = "${var.prefix}NIC-PRD1"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location

    ip_configuration {
        name                          = "${var.prefix}IP-PRD1"
        subnet_id                     = azurerm_subnet.prd-subnet.id
        private_ip_address_allocation = "Dynamic"
        public_ip_address_id          = azurerm_public_ip.ip-prd-1.id
    }
}

resource "azurerm_virtual_machine" "vm-prd-1" {
    name                  = "${var.prefix}VM-PRD-1"
    location              = var.location
    resource_group_name   = azurerm_resource_group.resourcegroup.name
    network_interface_ids = [azurerm_network_interface.nic-prd-1.id]
    vm_size               = var.size

    delete_os_disk_on_termination    = true
    delete_data_disks_on_termination = true

    storage_image_reference {
        publisher         = "credativ"
        offer             = "Debian"
        sku               = "9-backports"
        version           = "latest"
    }

    storage_os_disk {
        name              = "lin-disk-1"
        caching           = "ReadWrite"
        create_option     = "FromImage"
        managed_disk_type = "Standard_LRS"
    }

    os_profile {
        computer_name  = "${var.prefix}IP-PRD1"
        admin_username = "ADM-ADV"
        admin_password = "!!W0rksh0p"
    }

    os_profile_linux_config {
        disable_password_authentication = false
    }

    tags = {
        environment = "Production"
        application = "CTI Core"
    }
}








resource "azurerm_public_ip" "ip-prd-2" {
    name                = "${var.prefix}PIP-PRD-2"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location
    allocation_method   = "Dynamic"
    domain_name_label   = "vm-prd-2"
}


resource "azurerm_network_interface" "nic-prd-2" {
    name                = "${var.prefix}NIC-PRD-2"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location

    ip_configuration {
        name                          = "${var.prefix}IP-PRD-2"
        subnet_id                     = azurerm_subnet.prd-subnet.id
        private_ip_address_allocation = "Dynamic"
        public_ip_address_id          = azurerm_public_ip.ip-prd-2.id
    }
}

resource "azurerm_virtual_machine" "vm-prd-chef" {
    name                  = "${var.prefix}VM-PRD-CHEF"
    location              = var.location
    resource_group_name   = azurerm_resource_group.resourcegroup.name
    network_interface_ids = [azurerm_network_interface.nic-prd-2.id]
    vm_size               = var.size

    delete_os_disk_on_termination    = true
    delete_data_disks_on_termination = true

    storage_image_reference {
        publisher         = "Canonical"
        offer             = "UbuntuServer"
        sku               = "18.04-LTS"
        version           = "latest"
    }

    storage_os_disk {
        name              = "lin-disk-2"
        caching           = "ReadWrite"
        create_option     = "FromImage"
        managed_disk_type = "Standard_LRS"
    }

    os_profile {
        computer_name  = "${var.prefix}IP-PRD-CHEF"
        admin_username = "XXX"
        admin_password = "XXX"
    }

    os_profile_linux_config {
        disable_password_authentication = false
    }

    tags = {
        environment = "Production"
        application = "CTI Service"
    }

    provisioner "remote-exec" {
        inline = [
            "touch /root/test.txt"
        ]
    }

}

variables.tf 的内容

variable "prefix" {
    type            = string
    default         = "CTI-"
    description     = "Prefix of the resources"
}

variable "location" {
    type            = string
    default         = "westeurope"
    description     = "Location of the resources"
}

variable "size" {
    type            = string
    default         = "Standard_A1_v2"
    description     = "Size of the virtual machines"
}

谢谢你的帮助！

标签： azurenetworkingterraform

解决方案

根据您提供的消息，您希望在 Vnet 的现有子网中创建另一个 VM。所以你需要使用数据资源而不是资源格式。像这样更改您的 Terraform 代码：

改变：

resource "azurerm_virtual_network" "network" {
    name                = "${var.prefix}NETWORK"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    address_space       = ["10.0.0.0/16"]
    location            = var.location
}

resource "azurerm_subnet" "prd-subnet" {
    name                 = "${var.prefix}PRD"
    resource_group_name  = azurerm_resource_group.resourcegroup.name
    virtual_network_name = azurerm_virtual_network.network.name
    address_prefix       = "10.0.0.0/24"
}

进入：

data "azurerm_virtual_network" "network" {
  name                = "${var.prefix}NETWORK"
  resource_group_name = azurerm_resource_group.resourcegroup.name
}

data "azurerm_subnet" "prd-subnet" {
    name = "${var.prefix}PRD"
    virtual_network_name = data.azurerm_virtual_network.network.name
    resource_group_name = azurerm_resource_group.resourcegroup.name
}

resource "azurerm_network_interface" "nic-prd-1" {
    name                = "${var.prefix}NIC-PRD1"
    resource_group_name = azurerm_resource_group.resourcegroup.name
    location            = var.location

    ip_configuration {
        name                          = "${var.prefix}IP-PRD1"
        subnet_id                     = data.azurerm_subnet.prd-subnet.id
        private_ip_address_allocation = "Dynamic"
        public_ip_address_id          = azurerm_public_ip.ip-prd-1.id
    }
}

Terraform 数据将引用现有资源并且不会更改它们。如果另一个子网tst-subnet也存在，您可以像上面一样更改它。

推荐阅读