时间戳

首页 > 解决方案 > 从范围中排除多个单元格

excel - 从范围中排除多个单元格

问题描述

我的问题是如何从范围对象中删除一个或多个单元格？我之前问过一些非常相似的问题，有些人向我指出了这个问题：Remove cell from Range (object)

接受的答案：

Function getExcluded(ByVal rngMain As Range, rngExc As Range) As Range
    Dim rngTemp     As Range
    Dim rng         As Range

    Set rngTemp = rngMain
    Set rngMain = Nothing

    For Each rng In rngTemp
        If rng.Address <> rngExc.Address Then
            If rngMain Is Nothing Then
                Set rngMain = rng
            Else
                Set rngMain = Union(rngMain, rng)
            End If
        End If
    Next

    Set getExcluded = rngMain
End Function


Sub test()
    MsgBox getExcluded(Range("A1:M10000"), Range("a10")).Address
End Sub

接受的答案仅在排除范围是单个单元格时才有效 - 至少当我尝试它时对我来说是这样。我要排除的单元格通常不止一个单元格，因此我尝试调整代码：

我的尝试：

Function getExcluded(ByVal rngMain As Range, rngExcl As Range) As Range
    Dim rngTemp As Range
    Dim cellTemp As Range, cellExcl As Range

    Set rngTemp = rngMain
    Set rngMain = Nothing

    For Each cellTemp In rngTemp 'go through all cells in established range
        If Intersect(cellTemp, rngExcl) Is Nothing Then 'check for each cell if it intersects with the range to be excluded; no overlap -> put it into rngMain
            If rngMain Is Nothing Then
                Set rngMain = cellTemp
            Else
                rngMain = Union(rngMain, cellTemp)
            End If

            Debug.Print "cellTemp: " & cellTemp.Address
            Debug.Print "rngMain: " & rngMain.Address

        End If
    Next cellTemp

    Set getExcluded = rngMain


Sub test5()

    getExcluded(Range("A1:D3"), Range("B1:C1")).Select
End Sub

问题似乎发生在线路上Set rngMain = Union(rngMain, rng)。我的Debug.Print陈述告诉我，cellTemp它应该被迭代；然而，即使与Union被执行的行，不管是什么cellTemp，rngMain保持$A$1

我究竟做错了什么？

标签： excelvbarange

解决方案

像这样，也设置联合范围

Function testexclude(rngMain As Excel.Range, rngExclude As Excel.Range) As Excel.Range

Dim c As Excel.Range
Dim r As Excel.Range

For Each c In rngMain

    If Intersect(c, rngExclude) Is Nothing Then
        If r Is Nothing Then
            Set r = c
        Else
            Set r = Union(r, c)
        End If
    End If

Next c

Set testexclude = r

End Function

推荐阅读