时间戳

首页 > 解决方案 > 基于返回类型的 Fortran 泛型函数

function - 基于返回类型的 Fortran 泛型函数

问题描述

我正在尝试根据要返回的值在 Fortran 中创建一个通用函数，也就是说，取决于函数的输出是分配给单精度实数还是双精度实数。代码是：

MODULE kk_M

   USE ISO_FORTRAN_ENV

   IMPLICIT NONE

   INTEGER, PARAMETER :: sp = REAL32
   INTEGER, PARAMETER :: dp = REAL64

   INTERFACE use_func
      MODULE PROCEDURE use_sp_func
      MODULE PROCEDURE use_dp_func
   END INTERFACE use_func

   INTERFACE use_sub
      MODULE PROCEDURE use_sp_sub
      MODULE PROCEDURE use_dp_sub
   END INTERFACE use_sub

   CONTAINS

   FUNCTION use_sp_func() RESULT(res)
      REAL(KIND=sp) :: res
      res = 5._sp
   END FUNCTION use_sp_func

   FUNCTION use_dp_func() RESULT(res)
      REAL(KIND=dp) :: res
      res = 5._dp
   END FUNCTION use_dp_func

   SUBROUTINE use_sp_sub(res)
      REAL(KIND=sp), INTENT(OUT) :: res
      res = 5._sp
   END SUBROUTINE use_sp_sub

   SUBROUTINE use_dp_sub(res)
      REAL(KIND=dp), INTENT(OUT) :: res
      res = 5._dp
   END SUBROUTINE use_dp_sub

END MODULE kk_M


PROGRAM kk
   USE kk_M
   IMPLICIT NONE
   REAL(KIND=sp) :: num_sp
   REAL(KIND=dp) :: num_dp

   num_sp = use_func()
   WRITE(*,*) num_sp

   num_dp = use_func()
   WRITE(*,*) num_dp

   CALL use_sub(num_sp)
   WRITE(*,*) num_sp

   CALL use_sub(num_dp)
   WRITE(*,*) num_dp

END PROGRAM kk

使用通用子例程，代码可以编译并工作，但是当我添加通用函数时，它不会编译。我使用 gfortran 收到以下错误消息：

kk.f90:22:3:

    FUNCTION use_sp_func() RESULT(res)                                                                                                                                             
   1
kk.f90:27:3:

    FUNCTION use_dp_func() RESULT(res)                                                                                                                                             
   2
Error: Ambiguous interfaces in generic interface 'use_func' for ‘use_sp_func’ at (1) and ‘use_dp_func’ at (2)
kk.f90:46:7:

    USE kk_M
       1
Fatal Error: Can't open module file ‘kk_m.mod’ for reading at (1): No existe el archivo o el directorio
compilation terminated.

看起来编译器无法根据要返回的值区分这两个函数。有没有办法做到这一点？

标签： functionfortrangeneric-programming

解决方案

您无法通过返回值来区分通用接口中的特定函数。编译器无法查看要使用的返回值类型。Fortran 表达式总是在没有周围上下文的情况下进行评估。Fortran 通用消歧基于仅使用过程参数而不使用返回值的 TKR（类型、种类、等级）解析。

当你有

use_func()

编译器无法知道应该调用这两个函数中的哪一个。即使它直接在作业中使用

 x = use_func()

它是单独评估的。一般来说，函数调用可以出现在各种复杂的表达式中。例如use_func(use_func()) + use_func()，哪个是哪个？

这就是为什么几个内部函数有另一个参数来指定返回类型的原因。例如，该transfer()函数有第二个参数，用于指定应返回的类型。否则编译器将无法找到。

推荐阅读