windows - 从 Windows 注册表保存和检索布尔值

Question

我正在尝试使用 Delphi Rio (Firemonkey) 从 Windows 注册表中保存/检索布尔值。无论我保存哪种状态，真或假，代码总是返回一个真值。这是一个说明我的方法的示例项目：

uses
  System.IniFiles, System.Win.Registry;

const
  AppRegKey = 'Software\Mycroft\TestApp';

procedure TForm2.btnReadClick(Sender: TObject);
var
  Reg: TCustomIniFile;
  checked: boolean;
begin
  Reg := TRegistryIniFile.Create('');
  checked := False;
  if Reg.SectionExists(AppRegKey + '\State\BoxChecked') then begin
    checked := Reg.ReadBool(AppRegKey,'Show', True);
  end;
  if checked then
    ShowMessage('Checked')
  else
    ShowMessage('Unchecked');
end;

procedure TForm2.btnSaveClick(Sender: TObject);
var
  Reg: TCustomIniFile;

begin
  Reg := TRegistryIniFile.Create('');
  Reg.WriteBool(AppRegKey + '\State\BoxChecked', 'Show', chkBrandNew.IsChecked);
end;

看来注册表中的值正在更新，所以我不确定为什么它总是返回 True 值。有人可以指出我正确的方向吗？

标签： windowsdelphiregistryfiremonkeydelphi-10.3-rio

Answer 1

您没有将相同的键名Reg.ReadBool()传递给您传递给Reg.WriteBool().

您也在泄漏TRegistryIniFile对象。

试试这个：

uses
  System.IniFiles, System.Win.Registry;

const
  AppRegKey = 'Software\Mycroft\TestApp';
  AppRegKey_BoxChecked = AppRegKey + '\State\BoxChecked';

procedure TForm2.btnReadClick(Sender: TObject);
var
  Reg: TCustomIniFile;
  checked: boolean;
begin
  Reg := TRegistryIniFile.Create('');
  try
    checked := False;
    if Reg.SectionExists(AppRegKey_BoxChecked) then
    begin
      checked := Reg.ReadBool(AppRegKey_BoxChecked, 'Show', True);
    end;
    if checked then
      ShowMessage('Checked')
    else
      ShowMessage('Unchecked');
  finally
    Reg.Free;
  end;
end;

procedure TForm2.btnSaveClick(Sender: TObject);
var
  Reg: TCustomIniFile;
begin
  Reg := TRegistryIniFile.Create('');
  try
    Reg.WriteBool(AppRegKey_BoxChecked, 'Show', chkBrandNew.IsChecked);
  finally
    Reg.Free;
  end;
end;

也就是说，TRegistryIniFile是为了向后兼容用于保存配置TIniFile然后迁移到注册表的旧代码。根本不应该使用新代码TRegistryIniFile。

uses
  System.Win.Registry;

const
  AppRegKey = 'Software\Mycroft\TestApp';
  AppRegKey_BoxChecked = AppRegKey + '\State\BoxChecked';

procedure TForm2.btnReadClick(Sender: TObject);
var
  Reg: TRegistry;
  checked: boolean;
begin
  Reg := TRegistry.Create;
  //Reg := TRegistry.Create(KEY_QUERY_VALUE);
  try
    checked := False;
    if Reg.OpenKeyReadOnly(AppRegKey_BoxChecked) then
    // if Reg.OpenKey(AppRegKey_BoxChecked, False) then
    begin
      if Reg.ValueExists('Show') then
        checked := Reg.ReadBool('Show')
      else
        checked := True;
      Reg.CloseKey;
    end;
    if checked then
      ShowMessage('Checked')
    else
      ShowMessage('Unchecked');
  finally
    Reg.Free;
  end;
end;

procedure TForm2.btnSaveClick(Sender: TObject);
var
  Reg: TRegistry;
begin
  Reg := TRegistry.Create(KEY_SET_VALUE);
  try
    if Reg.OpenKey(AppRegKey_BoxChecked, True) then
    begin
      Reg.WriteBool('Show', chkBrandNew.IsChecked);
      Reg.CloseKey;
    end;
  finally
    Reg.Free;
  end;
end;