时间戳

首页 > 解决方案 > 通过在 SAS 中用另一个前缀替换前缀来动态重命名变量

sas - 通过在 SAS 中用另一个前缀替换前缀来动态重命名变量

问题描述

我有很多具有相同前缀的变量，我想用我选择的另一个前缀替换这个前缀，更具体地说，我的变量被命名为 IPN_RAORAOR1 ... IPN_RAORAOR125 IPN_VOLVOLR17 ... IPN_VOLVOLR46 等等我想取那些 IPN_RAORAO、IPN_VOLVOL 等...并用 IPN_RAO、IPN_VOL 等替换它们我想在 sas 宏中处理它，因为我可能会在几十个其他数据集上多次遇到这个问题，现在我尝试了一些东西，但不是替换它添加一个的前缀，如果你能帮助我，那就太好了

%macro rename(inds,outds,varlist,prefixlist);

%local i vars prefix namelist renames;

%do i=1 %to %sysfunc(countw(&varlist,%str( )));
    %let vars=%scan(&varlist,&i,%str( ));
    %let prefix=%scan(&prefixlist,&i,%str( ));
    proc transpose data=&inds(obs=0 keep=&vars) out=names; run;
    proc sql noprint;

    select _name_ into : namelist separated by ' ' from names;
    quit;

    %let renames= %rename(vars=&namelist,prefix=&prefix);
    %end;

    data &outds;
    set &inds(rename=(&renames));
    run; 

%mend ; 

%rename(inds=test, outds=test2, varlist = IPN_AFFAFF: IPN_RAORAO: 
IPN_VOLVOL:, prefixlist =IPN_AFFR IPN_RAO IPN_VOL);

标签： sasprefix

解决方案

您可以从 sashelp.vcolumn 获取数据集中的变量列表。这比转置空数据集更容易。此外，宏变量“renames”可以直接在您的into:语句中使用catx().

在下面，我renames&i为前缀列表中的每个元素创建了一个新的宏变量。在我看来，这使代码更容易阅读。此外，我已分别将参数varlist和重命名prefixlist为oldprefixlist和newprefixlist。我觉得这些名字更合适。

%macro rename(inds,outds,oldprefixlist,newprefixlist);

   * For each pair of old and new prefixes, make a list of variables that should be renamed;
   %do i=1 %to %sysfunc(countw(&oldprefixlist,%str( )));
      proc sql noprint;
         select catx('=',name,tranwrd(name,"%scan(&oldprefixlist,&i,%str( ))","%scan(&newprefixlist,&i,%str( ))"))
            into :renames&i. separated by ' '
         from sashelp.vcolumn
         where libname='WORK' 
           and memname=upcase("&inds.")
           and index(upcase(name),upcase("%scan(&oldprefixlist,&i,%str( ))")) = 1
         ;
      quit;
   %end;

   * Make the output dataset including renamed variables;
   data &outds;
      set &inds;
      rename 
      %do i=1 %to %sysfunc(countw(&oldprefixlist,%str( )));
         &&renames&i.
      %end;;
   run; 

%mend; 


* Try it out with testdata;
data test;
input ipn_affaff1 $ ipn_raoraor1 ipn_raoraor125 $ ipn_volvolr17 $ ipn_volvolr46 $;
datalines;
a 1 b c d 
e 2 f g h
;
run;

%rename(inds           = test
       ,outds          = test2
       ,oldprefixlist  = ipn_affaff ipn_raorao ipn_volvol
       ,newprefixlist  = ipn_aff ipn_rao ipn_vol);

推荐阅读