xml - 如何使用 XMLSlurper 修改 XML 节点属性

Question

我正在尝试重命名父节点和子节点并编写类似这样的代码，

    def xml = (''' <resultset columns="13" rows="2">
    <row number="1">
    <enterpise>DE</enterpise>
    <line>0001</line>
    <name>DELL</name>
    <version>0.01</version>
    <updtae isnull="true"/>
    </row>
    <row number="2">
    <enterpise>DF</enterpise>
    <line>0002</line>
    <name>DELL</name>
    <version>0.01</version>
    <updtae isnull="true"/>
    </row>
    </resultset>
    ''')
def resultset = new XmlSlurper().parseText(xml) 
def record = resultset.record.find{ it.@columns=='13'}.each 
{ p -> p.attributes().13('columns') } 
resultset.row.replaceNode { row { tr { td("DE") } tr { td("0001") } } }

预期的结果是

<Row ss:AutoFitHeight="0">
    <tr><td ss:Type="String">DE</td></tr>
    <tr><td ss:Type="Number">0001</td></tr>
    <tr><td ss:Type="Sring">DELL</td></tr>
    <tr><td ss:Type="Number">0.01</td></tr>
    <tr><td ss:Type="String"></td></tr>
</Row>
<Row ss:AutoFitHeight="0">
    <tr><td ss:Type="String">DF</td></tr>
    <tr><td ss:Type="Number">0002</td></tr>
    <tr><td ss:Type="Sring">DELL</td></tr>
    <tr><td ss:Type="Number">0.01</td></tr>
    <tr><td ss:Type="String"></td></tr>
</Row>

我无法删除父（结果集）标签，而不是传递值“DE”或“0001”，我需要动态获取它。你能帮我完成这个吗

标签： xmlgroovy

Answer 1

以下代码：

import groovy.xml.* 

def inData = '''
<resultset columns="13" rows="2">
   <row number="1">
     <enterpise>DE</enterpise>
     <line>0001</line>
     <name>DELL</name>
     <version>0.01</version>
     <updtae isnull="true"/>
   </row>
   <row number="2">
     <enterpise>DF</enterpise>
     <line>0002</line>
     <name>DELL</name>
     <version>0.01</version>
     <updtae isnull="true"/>
   </row>
 </resultset>'''

def inXml = new XmlSlurper().parseText(inData)

def outData = new StringWriter()
def outXml = new MarkupBuilder(outData)

inXml.row.each { row -> 
  outXml.Row('ss:AutoFitHeights': 0) {
    tr { td('ss:Type': 'String', row.enterpise) }
    tr { td('ss:Type': 'Number', row.line)       }
    tr { td('ss:Type': 'String', row.name) }
    tr { td('ss:Type': 'Number', row.version) }
    tr { td('ss:Type': 'String') }
  }
}

println outData

运行时，产生以下输出：

─➤ groovy solution.groovy
output:
<Row ss:AutoFitHeights='0'>
  <tr>
    <td ss:Type='String'>DE</td>
  </tr>
  <tr>
    <td ss:Type='Number'>0001</td>
  </tr>
  <tr>
    <td ss:Type='String'>DELL</td>
  </tr>
  <tr>
    <td ss:Type='Number'>0.01</td>
  </tr>
  <tr>
    <td ss:Type='String' />
  </tr>
</Row>
<Row ss:AutoFitHeights='0'>
  <tr>
    <td ss:Type='String'>DF</td>
  </tr>
  <tr>
    <td ss:Type='Number'>0002</td>
  </tr>
  <tr>
    <td ss:Type='String'>DELL</td>
  </tr>
  <tr>
    <td ss:Type='Number'>0.01</td>
  </tr>
  <tr>
    <td ss:Type='String' />
  </tr>
</Row>

我认为这与您要创建的内容非常接近。通常，如果您尝试进行转换，而不仅仅是删除节点，则更容易创建一个全新的 xml 文档，如上面的代码所示。