excel - 如何为列中的每个“新”值创建一个新的工作簿?
问题描述
我正在尝试为特定列中的每个新值创建一个新的电子表格。
附上示例数据:
目前,我必须获取这些数据并通过公式将其推送,然后将公式输出的内容复制并粘贴到记事本文件中。
我想让它为 D 列中的每个新值制作一个新的电子表格,以便在示例中创建两个文件,并且每个文件的所有行都包含它。所以最终会得到一个包含 13 行的“86373”文件和一个包含 2 行的“86376”文件。
我是编写 VBA 的新手,这超出了我的专业知识范围,因此我目前没有可共享这部分宏的代码。感谢任何帮助!
这是我当前代码所在的位置:
Dim ShipmentField As Range
Dim ShipmentNum As Range
Dim NewWSheet As Worksheet
Dim WSheet As Worksheet
Dim WSheetFound As Boolean
Dim ShipmentWSheet As Worksheet
x.Worksheets("UPS_CSV_EXPORT").Activate 'x is set to the workbook that contains the date. Using macro in separate workbook.
Set ShipmentWSheet = Worksheets("UPS_CSV_EXPORT")
Set ShipmentField = ShipmentWSheet.Range("D2", ShipmentWSheet.Range("D2").End(xlDown))
Application.ScreenUpdating = False
For Each ShipmentNum In ShipmentField
For Each WSheet In x.Worksheets
If WSheet.Name = ShipmentNum Then
WSheetFound = True
Exit For
Else
WSheetFound = False
End If
Next WSheet
If WSheetFound Then
ShipmentNum.Offset(0, -3).Resize(1, 4).Copy Destination:=Worksheets(ShipmentNum.Value).Range("A1").End(xlDown).Offset(1, 0)
Else
Set NewWSheet = Sheets.Add(After:=x.Sheets(x.Sheets.Count))
Debug.Print ShipmentNum
NewWSheet.Name = ShipmentNum
ShipmentWSheet.Range("A1", ShipmentWSheet.Range("A1").End(xlToRight)).Copy Destination:=NewWSheet.Range("A1")
ShipmentNum.Offset(0, -3).Resize(1, 4).Copy Destination:=NewWSheet.Range("A2")
End If
Next ShipmentNum
Application.ScreenUpdating = True
我在该行收到“下标超出范围”错误:ShipmentNum.Offset(0, -3).Resize(1, 4).Copy Destination:=Worksheets(ShipmentNum.Value).Range("A1").End(xlDown).Offset(1, 0)
谢谢,科尔文
解决方案
这将做你想要的。
Sub Copy_With_AutoFilter1()
'Note: This macro use the function LastRow
Dim My_Range As Range
Dim CalcMode As Long
Dim ViewMode As Long
Dim FilterCriteria As String
Dim CCount As Long
Dim WSNew As Worksheet
Dim sheetName As String
Dim rng As Range
'Set filter range on ActiveSheet: A1 is the top left cell of your filter range
'and the header of the first column, D is the last column in the filter range.
'You can also add the sheet name to the code like this :
'Worksheets("Sheet1").Range("A1:D" & LastRow(Worksheets("Sheet1")))
'No need that the sheet is active then when you run the macro when you use this.
Set My_Range = Range("A1:D" & LastRow(ActiveSheet))
My_Range.Parent.Select
If ActiveWorkbook.ProtectStructure = True Or _
My_Range.Parent.ProtectContents = True Then
MsgBox "Sorry, not working when the workbook or worksheet is protected", _
vbOKOnly, "Copy to new worksheet"
Exit Sub
End If
'Change ScreenUpdating, Calculation, EnableEvents, ....
With Application
CalcMode = .Calculation
.Calculation = xlCalculationManual
.ScreenUpdating = False
.EnableEvents = False
End With
ViewMode = ActiveWindow.View
ActiveWindow.View = xlNormalView
ActiveSheet.DisplayPageBreaks = False
'Firstly, remove the AutoFilter
My_Range.Parent.AutoFilterMode = False
'Filter and set the filter field and the filter criteria :
'This example filter on the first column in the range (change the field if needed)
'In this case the range starts in A so Field 1 is column A, 2 = column B, ......
'Use "<>Netherlands" as criteria if you want the opposite
My_Range.AutoFilter Field:=1, Criteria1:="=Netherlands"
'If you want to filter on a cell value you can use this, use "<>" for the opposite
'This example uses the activecell value
'My_Range.AutoFilter Field:=1, Criteria1:="=" & ActiveCell.Value
'This will use the cell value from A2 as criteria
'My_Range.AutoFilter Field:=1, Criteria1:="=" & Range("A2").Value
''If you want to filter on a Inputbox value use this
'FilterCriteria = InputBox("What text do you want to filter on?", _
' "Enter the filter item.")
'My_Range.AutoFilter Field:=1, Criteria1:="=" & FilterCriteria
'Check if there are not more then 8192 areas(limit of areas that Excel can copy)
CCount = 0
On Error Resume Next
CCount = My_Range.Columns(1).SpecialCells(xlCellTypeVisible).Areas(1).Cells.Count
On Error GoTo 0
If CCount = 0 Then
MsgBox "There are more than 8192 areas:" _
& vbNewLine & "It is not possible to copy the visible data." _
& vbNewLine & "Tip: Sort your data before you use this macro.", _
vbOKOnly, "Copy to worksheet"
Else
'Add a new Worksheet
Set WSNew = Worksheets.Add(After:=Sheets(ActiveSheet.Index))
'Ask for the Worksheet name
sheetName = InputBox("What is the name of the new worksheet?", _
"Name the New Sheet")
On Error Resume Next
WSNew.Name = sheetName
If Err.Number > 0 Then
MsgBox "Change the name of sheet : " & WSNew.Name & _
" manually after the macro is ready. The sheet name" & _
" you fill in already exists or you use characters" & _
" that are not allowed in a sheet name."
Err.Clear
End If
On Error GoTo 0
'Copy/paste the visible data to the new worksheet
My_Range.Parent.AutoFilter.Range.Copy
With WSNew.Range("A1")
' Paste:=8 will copy the columnwidth in Excel 2000 and higher
' Remove this line if you use Excel 97
.PasteSpecial Paste:=8
.PasteSpecial xlPasteValues
.PasteSpecial xlPasteFormats
Application.CutCopyMode = False
.Select
End With
' If you want to delete the rows that you copy, also use this
' With My_Range.Parent.AutoFilter.Range
' On Error Resume Next
' Set rng = .Offset(1, 0).Resize(.Rows.Count - 1, .Columns.Count) _
' .SpecialCells(xlCellTypeVisible)
' On Error GoTo 0
' If Not rng Is Nothing Then rng.EntireRow.Delete
' End With
End If
'Close AutoFilter
My_Range.Parent.AutoFilterMode = False
'Restore ScreenUpdating, Calculation, EnableEvents, ....
My_Range.Parent.Select
ActiveWindow.View = ViewMode
If Not WSNew Is Nothing Then WSNew.Select
With Application
.ScreenUpdating = True
.EnableEvents = True
.Calculation = CalcMode
End With
End Sub
Function LastRow(sh As Worksheet)
On Error Resume Next
LastRow = sh.Cells.Find(What:="*", _
After:=sh.Range("A1"), _
Lookat:=xlPart, _
LookIn:=xlValues, _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Row
On Error GoTo 0
End Function
你可以在这里找到更多信息。
推荐阅读
- .net - 试图了解 RSACryptoServiceProvider 密钥和消息长度关系
- java - Java图像未出现在jar应用程序中
- angular - Angular 编译器中纯打字稿库的“未找到模块”
- graphql - 在 Amplify ReactJs 中删除和更新 Graphql 突变
- node.js - @angular-cli install 失败,请求被弃用@2.88.2:请求已被弃用(mac)
- javascript - FullCalendar v4 - fullCalendar 不是函数
- json - Jenkins - 将 curl 输出存储到文件中以供将来使用
- node.js - 如何在开发 VSCode 扩展时使用 node-sass?
- c - 如何使用 C 中的中序遍历编写递归函数来搜索二叉树中的键?
- triggers - 如何根据控制表中的最新记录触发 Google Cloud Composer DAG