时间戳

首页 > 解决方案 > 如何取消线程？

vb.net - 如何取消线程？

问题描述

我在一个线程中做某事。但有时我不想等到所有 ping 都完成。

如何取消线程？

你能告诉我代码吗？

Private Sub Start_Button_Click(sender As Object, e As EventArgs) Handles Start_Button.Click
    DoSomething()
End Sub
Private Sub Cancel_Button_Click(sender As Object, e As EventArgs) Handles Cancel_Button.Click
    THRD.Cancel '<-- Thread cancel!??!???
End Sub
Sub DoSomething()
    Dim THRD As New Thread(Sub()
                               Dim IPArea As String = "192.168.1."
                               Dim LastIP As Integer
                               For LastIP = 0 To 255
                                   Dim TestIP As String = IPArea & CStr(LastIP)
                                   If My.Computer.Network.Ping(TestIP, 10) Then
                                       ListBox1.Items.Add(TestIP)
                                   End If
                               Next
                           End Sub)
    THRD.IsBackground = True
    THRD.Start()
End Sub

标签： vb.netmultithreading

解决方案

这是我的工作解决方案，该解决方案仅展示如何将其THRD作为表单级别变量移动以允许在单击取消按钮时停止它。我添加了一些验证来防止异常。

Public Class Form1
    Private THRD As Threading.Thread

    Private Sub Start_Button_Click(sender As Object, e As EventArgs) Handles Start_Button.Click
        DoSomething()
    End Sub
    Private Sub Cancel_Button_Click(sender As Object, e As EventArgs) Handles Cancel_Button.Click

        If THRD IsNot Nothing AndAlso THRD.IsAlive Then
            THRD.Abort()  '<-- Thread cancel!??!???
            THRD = Nothing
            AddToList("Stopped.")
        Else
            AddToList("Thread not running.")
        End If
    End Sub

    Sub DoSomething()
        If THRD IsNot Nothing AndAlso THRD.IsAlive Then
            AddToList("Still working...")
            Exit Sub
        End If

        THRD = New Threading.Thread(Sub()
                                        Dim IPArea As String = "192.168.1."
                                        Dim LastIP As Integer
                                        For LastIP = 0 To 255
                                            Dim TestIP As String = IPArea & CStr(LastIP)
                                            If My.Computer.Network.Ping(TestIP, 10) Then
                                                AddToList(TestIP)
                                            End If
                                        Next
                                        AddToList("Done")
                                    End Sub)
        THRD.IsBackground = True
        THRD.Start()
    End Sub

    ''' <summary>
    ''' Thead-safe add value to list.
    ''' </summary>
    ''' <param name="value">The value.</param>
    Private Sub AddToList(value As String)
        If ListBox1.InvokeRequired Then
            ListBox1.Invoke(Sub() ListBox1.Items.Add(value))
        Else
            ListBox1.Items.Add(value)
        End If
    End Sub
End Class

推荐阅读