时间戳

首页 > 解决方案 > 在 Forth 上将文本文件写入数组

arrays - 在 Forth 上将文本文件写入数组

问题描述

我有一个文本文件，其中包含一个数字数组，例如：

1 0 0 1 0
0 1 1 0 1
0 0 0 1 1
1 1 0 0 0
0 0 1 0 0

我用以下代码打开了文本文件：

variable file-id
: open_file ( -- ) \ Opens the text file
  s" c:\etc\textfile.txt" r/w open-file throw
  file-id ! ;

我还创建了一个数组来存储这些数据：

create an_array 25 chars allot \ Create the array

: reset_array ( -- ) big_array 25 0 fill ;
reset_array \ Set all elements to 0

有没有办法用 Forth 将文本文件的内容写入数组？

标签： arraystext-filesforthgforth

解决方案

1.懒惰的方式

一种懒惰的方法是通过included对文件名执行来评估文件。

\ Some library-level common words
\ --------------------------------

\ Store n chars from the stack into the array at c-addr, n >= 0
: c!n ( n*x n c-addr -- )
  >r begin dup while ( i*x i )
    \ store top from i*x into addr+(i-1)*char_size
    1- tuck chars r@ + c! ( j*x j )
  repeat drop rdrop
;

\ Execute xt and produce changing in the stack depth
: execute-balance ( i*x xt -- j*x n ) depth 1- >r execute depth r> - ;

: included-balance ( i*x c-addr u -- j*x n )
  ['] included execute-balance 2 +
;

\ The program
\ --------------------------------

create myarray 25 chars allot \ Create the array

: read-myfile-numbers ( -- i*x i )
  state @ abort" Error: only for interpretation"
  s" ./mynumbers.txt" included-balance
;
: write-myarray ( i*x i -- )
  dup 25 <> abort" Error: exactly 25 numbers are expected"
  myarray c!n
;
: fill-myarray-from-myfile ( -- )
  read-myfile-numbers write-myarray
;

2.整洁的方式

一种谨慎的方法是读取文件（完整或逐行），将文本拆分为词位，将词位转换为数字，然后将数字存储到数组中。

请参阅：如何在 Forth 中输入数字。

在低级别上，它可以通过read-fileor来完成read-line，类似于word|tailand >number（或类似于StoN上面示例中的库词）。

在更高的层次上：使用 Gforth 特定的词，如execute-parsingor execute-parsing-file，parse-name和s>number?

: next-lexeme ( -- c-addr u|0 )
  begin parse-name ?dup if exit then ( addr )
    refill 0= if 0 exit then drop
  again
;
: read-myfile-numbers ( -- i*x i )
  s" ./mynumbers.txt" r/o open-file throw
  [:
    0 begin next-lexeme dup while
      s>number? 0= abort" Error: NaN" d>s swap 1+
    repeat 2drop
  ;] execute-parsing-file
;

如果需要读取的数字太多，就必须一次一个地将它们写入数组，而不是全部放入堆栈。

推荐阅读