时间戳

首页 > 解决方案 > Inno Setup 语言文件 (isl) 中的完整预处理器支持

inno-setup - Inno Setup 语言文件 (isl) 中的完整预处理器支持

问题描述

我在安装程序中使用了三种语言，目前我正在脚本中进行所有覆盖。这是一个例子：

[Messages]
en.SetupWindowTitle=Setup - %1 {#AppVersion}
ru.SetupWindowTitle=Установка - %1 {#AppVersion}
ua.SetupWindowTitle=Встановлення - %1 {#AppVersion}
en.SetupAppRunningError=Setup has detected that {#SetupSetting('VersionInfoOriginalFileName')} is currently running.%n%nPlease close all instances of it now, then click OK to continue, or Cancel to exit.
ru.SetupAppRunningError=Обнаружен запущенный экземпляр {#SetupSetting('VersionInfoOriginalFileName')}.%n%nПожалуйста, закройте все экземпляры приложения, затем нажмите «OK», чтобы продолжить, или «Отмена», чтобы выйти.
ua.SetupAppRunningError=Виявлено запущений екземпляр {#SetupSetting('VersionInfoOriginalFileName')}.%n%nБудь ласка, закрийте всі копії програми та натисніть «OK» для продовження, або «Скасувати» для виходу.
[CustomMessages]
en.AppRunningError=Setup has detected that {#AppExeName} is currently running.%n%nPlease, close the {#AppExeName} application, then click «OK» to continue or «Cancel» to exit. 
ru.AppRunningError=В памяти находится {#AppExeName}.%n%nЗавершите работу {#AppExeName} и нажмите «OK», чтобы продолжить, или «Отмена», чтобы выйти. 
ua.AppRunningError=В пам'яті знаходиться {#AppExeName}.%n%nЗавершіть роботу {#AppExeName} та натисніть «OK» для продовження, або «Скасувати» для виходу.

我在脚本中有很多消息被覆盖。.isl考虑到我使用了预处理器指令，我想知道将所有这些覆盖转移到文件中的最有效方法是什么{#...}。我可以使用FmtMessage(...)，但这意味着我必须包含FmtMessage(...)每条消息。

标签： inno-setup

解决方案

首先检查，如果一些侵入性较小的解决方案可能无法满足您的需求：
我可以在 Inno Setup 中使用带有预处理器指令的消息的 .isl 文件吗？

如果你想在 .isl 文件中获得完整的预处理器支持，你可以通过实际的 Inno Setup 预处理器传递它们：

  • defines.iss将包含所有变量定义（和一些支持代码）的通用包含文件 ( ) 分解出来：

    // Definitions
#define AppVersion "1.2.3"
// more definitions ...

// Support code
#define PreprocessedTranslationFile GetEnv("TEMP") + "\lang.isl"
#define SavePreprocessedTranslation() SaveToFile(PreprocessedTranslationFile)

  • 在 .iss 和所有 .isl 的开头包含该文件：

    #include "defines.iss"

  • SavePreprocessedTranslation在所有 .isl 文件的末尾调用：

    #expr SavePreprocessedTranslation()

  • iscc对修改后的 .isl 文件进行预处理器调用。它当然会失败，因为 .isl 不是有效的 .iss，但预处理器部分iscc应该完成并创建预处理的 .isl 文件。

    #define DebugPreprocessLanguage 0

#define PreprocessLanguage(Path) \
  Local[0] = "C:\Program Files (x86)\Inno Setup 6\ISCC.exe", \
  DeleteFileNow(PreprocessedTranslationFile), \
  Local[1] = DebugPreprocessLanguage ? SourcePath + "\islpreprocess.log" : "nul", \
  Local[2] = "/C """"" + Local[0] + """ """ + Path + """ " + \
             ">> " + Local[1] + " 2>&1 """, \
  Exec("cmd", Local[2], SourcePath, , SW_HIDE), \
  (FileExists(PreprocessedTranslationFile) || \
    Error(Path + " failed to preprocess")), \
  Local[3] = GetEnv("TEMP") + "\" + ExtractFileName(Path), \
  CopyFile(PreprocessedTranslationFile, Local[3]), \
  DeleteFileNow(PreprocessedTranslationFile), \
  Local[3]

  • 并使用该[Languages]部分中预处理的 .isl 文件。

    [Languages]
Name: "en"; MessagesFile: {#PreprocessLanguage("Default.isl")}
Name: "nl"; MessagesFile: {#PreprocessLanguage("Dutch.isl")}

如果您有问题，请设置DebugPreprocessLanguage为1查看 .isl 预处理器输出。

您甚至可以通过让预处理器在调用 .isl 之前将#include "defines.iss"和自动添加到 .isl 来改进该过程。#expr SavePreprocessedTranslation()iscc

推荐阅读