时间戳

首页 > 解决方案 > Haskell 中存在类型的编译问题

haskell - Haskell 中存在类型的编译问题

问题描述

我写了一个简单的类型类Shape：

class Shape a where
  draw   :: a -> IO ()
  move   :: (Double,Double) -> a -> a
  area   :: a -> Double
  circum :: a -> Double

我也有具体的类型Circle，Rect并且Triangle像这样实例化这个类型类：

data Circle = Circle Point Double deriving (Show)

instance Shape Circle where
  draw       (Circle centre radius) = putStrLn $ "Circle [" ++ show centre ++ ", " ++ show radius ++ "]"
  move (x,y) (Circle centre radius) = Circle (movePoint x y centre) radius
  area   (Circle _ r) = r ^ 2 * pi
  circum (Circle _ r) = 2 * r * pi

movePoint :: Double -> Double -> Point -> Point
movePoint x y (Point x_a y_a) = Point (x_a + x) (y_a + y)

为了使用包含具体类型实例的异构列表，Circle我遵循了关于异构集合的 haskell wiki 教程并实现了一个存在数据类型，如下所示：RectTriangleShapeType

{-# LANGUAGE ExistentialQuantification #-}

data ShapeType = forall a . Shape a => MkShape a

我让ShapeType实例化Shape类型类：

instance Shape ShapeType where
  area     (MkShape s) = area s
  circum   (MkShape s) = circum s
  draw     (MkShape s) = draw s
  move (x,y) (MkShape s) =  move (x,y) s  -- this does not compile

现在我可以在如下代码中使用它：

rect = Rect (Point 0 0) (Point 5 4)
circle = Circle (Point 4 5) 4
triangle = Triangle (Point 0 0) (Point 4 0) (Point 4 3)

shapes :: [ShapeType]
shapes = [MkShape rect, MkShape circle, MkShape triangle]

main = do
  print $ map area shapes
  print $ map circum shapes
  mapM_ draw shapes

不幸的是，这只有在我省略该行时才能编译

move (x,y) (MkShape s) = move (x,y) s

否则我会收到以下编译错误：

error:
    * Couldn't match expected type `ShapeType' with actual type `a'
      `a' is a rigid type variable bound by
        a pattern with constructor:
          MkShape :: forall a. Shape a => a -> ShapeType,
        in an equation for `move'
        at C:\\workspace\FPvsOO\src\Lib.hs:102:15-23
    * In the expression: move (x, y) s
      In an equation for `move': move (x, y) (MkShape s) = move (x, y) s
      In the instance declaration for `Shape ShapeType'
    * Relevant bindings include
        s :: a (bound at C:\\workspace\FPvsOO\src\Lib.hs:102:23)

这对我来说没有意义，因为s在其他三种情况下，“提取”模式匹配以供在委托调用中使用可以正常工作。

任何想法这里出了什么问题？

更新

通过这个简单的修复，代码现在可以按预期工作：

instance Shape ShapeType where
  area     (MkShape s) = area s
  circum   (MkShape s) = circum s
  draw     (MkShape s) = draw s
  move vec (MkShape s) = MkShape (move vec s)

标签： haskellexistential-typeheterogeneousheterogeneous-array

解决方案

你错过了一个构造函数。你需要

move v (MkShape s) = MkShape $ move v s

我不太相信您在这里的方法确实是最好的。在这种情况下，存在主义类型往往只会把作品搞砸。您至少应该考虑一个普通的旧 sum 类型。存在主义在某些方面是无价的，但在其他情况下，它们是有害的。

推荐阅读