时间戳

首页 > 解决方案 > 试图计算总工资

lisp - 试图计算总工资

问题描述

我正在尝试创建一个程序，该程序将每周计算员工的总工资。

这是我的代码

(princ"Enter working hours: ")
(defparameter workhours(read))
(if (and (>= workhours 0)) (<= workhours 60))
    (princ"Enter hourly pay rate: ")
    (defparameter HPrate(read))
    (if(<= workhours 40)
        (* workhours HPrate))

我很难用 lisp 构建这个 40*HPrate + (workhours - 40) * HPrate * 1.5

这是公式

(Regular hours/week) Gross Pay = Hours X Rate
(With Overtime) Over Time Pay = ( Hours - 40 ) X Rate X 1.5
Gross Pay = 40 X Rate + Over Time Pay

标签： lispcommon-lispclisp

解决方案

您应该尝试将代码的逻辑与输入/输出操作分开，例如询问数字或写入结果。通常最好只编写给定数字和输出数字的函数。然后，您可以从任何类型的用户界面（图形或文本）调用它。

商业逻辑

您想计算给定工作时间数和小时费率的总工资。

因此，您定义了一个名为 的函数，gross-pay它将 awork-hours和 a的数量作为输入hourly-rate：

(defun gross-pay (work-hours hourly-rate)
  10000 ;; a lot of money, just for testing
  )

现在它已经定义好了，你可以调用它，你的环境会自动打印结果：

* (gross-pay 0 0)
10000

您的代码中的一个问题是您有一个if包含一个测试和三个分支的分支，这不是有效的语法。根据你写的，我猜你想要这个逻辑：

(defun gross-pay (work-hours hourly-rate)
  (assert (<= 0 work-hours 60))
  ;; ...
  )

检查条件是否成立，assert否则发出错误信号。我认为如果小时数低于零或大于 60，则没有有效的计算，在这种情况下出现错误是有意义的。

然后，您想使用您提供的公式计算总工资。

您必须计算正常工作时间、加班时间，并以不同的方式对这两种工作时间进行定价（并将它们相加）。

让我们定义一个辅助函数 ，split-time它返回两个值，小于或等于 40 的小时数，以及剩余时间（超过 40）：

(defun split-time (hours)
  (if (> hours 40)
      ;; the regular amount is maxed to 40
      ;; overtime is the rest
      (values 40 (- hours 40))
      ;; regular amount is the same as the input
      ;; no overtime
      (values hours 0)))

values使用可以得到多个结果multiple-value-bind，如下：

(defun gross-pay (work-hours hourly-rate)
  (assert (<= 0 work-hours 60))
  (multiple-value-bind (regular overtime) (split-time work-hours)
    ;; here regular and overtime are bound to values
    ))

最后：

(defun gross-pay (work-hours hourly-rate)
  (assert (<= 0 work-hours 60))
  (multiple-value-bind (regular overtime) (split-time work-hours)
    (+ (* regular  hourly-rate)
       (* overtime hourly-rate 3/2))))

在这里，我使用3/2而不是1.5因为浮点计算是近似的，但有理数是精确的。例如，结果可以在打印时转换回浮点数。

测试

现在你有了一个函数，你可以测试它：

* (gross-pay 10 1)
10

* (= (gross-pay 50 1)
     (+ (* 40 1) 
        (* 10 3/2)))
T

输入输出

如果需要，您可以将逻辑包装在命令行界面中：

(defun gross-pay/io ()
  (gross-pay
   (ask "Enter working hours: " '(integer 0 60))
   (ask "Enter hourly pay rate: " '(integer 1 1000))))

上面的工作要归功于这个辅助函数，它处理在请求输入时可能出现的不同问题（清除缓冲、强制输出、读取值时禁用评估、检查类型等）

(defun ask (prompt type)
  (let ((*standard-output* *query-io*))
    (loop
      (clear-input)
      (fresh-line)
      (princ prompt)
      (finish-output)
      (let ((value (let ((*read-eval* nil)) (read))))
        (if (typep value type)
            (return value)
            (format *error-output*
                    "type mismatch: ~a not of type ~a"
                    value type))))))

在我的环境中，这是一个示例交互：

USER> (gross-pay/io)

Enter working hours: 5

Enter hourly pay rate: 3

15

还有一个错误输入的例子：

Enter working hours: 87
type mismatch: 87 not of type (INTEGER 0 60)
Enter working hours: ""
type mismatch:  not of type (INTEGER 0 60)
Enter working hours: 15

Enter hourly pay rate: 0
type mismatch: 0 not of type (INTEGER 1 1000)
Enter hourly pay rate: 88

1320

推荐阅读